0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
5 'Music Simon Says, by Russ Hall
10 DATA 4697,3728,3134,2348
15 DIMB(30)
20 FORA=1TO4:READS(A):NEXT
40 B$="":L=25:H=0
41 CLS:LINE(4,8)-(235,60),1,B:PRINT@90,"<C>omputer Simon":PRINT@130,"<T>wo player Simon":PRINT@170,"<M>etronome":PRINT@210,"<I>nstructions":PRINT@250,"<Q>uit"
42 GOSUB400
43 IFA$="Q"ORA$="q"THENMENU
44 IFA$="C"ORA$="c"THEN500
45 IFA$="T"ORA$="t"THEN50
46 IFA$="M"ORA$="m"THEN1000
47 IFA$="I"ORA$="i"THEN2000
48 GOTO42
50 CLS:PRINTTAB(12)"MUSIC SIMON":H=H+1
60 PRINT@80,"First Player: ":GOSUB100:PRINT@80,"Second Player?":PRINT@180,"          ":GOSUB200
70 GOSUB350:GOTO50
100 IFB$=""THEN250:RETURN' first player
101 FORA=1TOLEN(B$)-1STEP2:B=VAL(MID$(B$,A,2))
110 GOSUB400:IFVAL(A$)=BTHENGOSUB300ELSEGOTO230
130 NEXT:GOTO250
200 FORA=1TOLEN(B$)-1STEP2:B=VAL(MID$(B$,A,2))'  second player
220 GOSUB400:IFVAL(A$)=BTHENGOSUB300:GOTO240
230 PRINT@160," WRONG!":SOUND14912,30:FORA=1TO1000:NEXT
235 IFH>HIGHTHENHIGH=H:PRINT@160,"NEW LONGEST TUNE,"HIGH"NOTES":FORA=1TO1000:NEXT:GOTO40ELSEGOTO40
240 NEXT:RETURN
250 PRINT@180,"NEXT NOTE?"'another note
251 '
252 GOSUB400:IFVAL(A$)<1ORVAL(A$)>4THEN251
253 B=VAL(A$):B$=B$+STR$(VAL(A$)):GOSUB300:RETURN
300 IFB=0THENRETURN'  sound routine
310 PRINT@277+B*5,CHR$(239);:SOUNDS(B),L:FORG=0TO10:NEXT
340 PRINT@280,STRING$(20,32);:RETURN
350 IFLEN(B$)>6THENL=15
360 IFLEN(B$)>12THENL=5:RETURNELSERETURN
400 A$=INKEY$:IFA$=""THEN400
410 RETURN
500 CLS:PRINTTAB(12)"MUSIC SIMON"
510 H=H+1:PRINT@80,"MY TURN...":GOSUB560:PRINT@80,"YOUR TURN:":GOSUB200
520 FORA=1TO500:NEXT:GOSUB350:GOTO510
560 FORA=1TOLEN(B$)-1STEP2:B=VAL(MID$(B$,A,2)):GOSUB300:NEXT
570 B=INT(RND(1)*4)+1:B$=B$+STR$(B):GOSUB300:RETURN
1000 CLS:PRINT:PRINT"IS TIME 3/4 OR 4/4?"
1010 GOSUB400
1020 IFA$="3"ORA$="4"THEN1040ELSE1010
1040 PRINT:INPUT"WHAT IS THE TEMPO? (beats/minute)";G
1060 G=330-G:PRINT:PRINT" Press 'Q' anytime to quit"
1080 SOUND 7000,3:FORT=1TOG:NEXT
1100 FORS=1TOVAL(A$)-1:SOUND 7000,1
1120 FORT=1TOG:NEXT:NEXT
1130 Q$=INKEY$:IFQ$="Q"ORQ$="q"THEN40
1150 GOTO1080
2000 CLS:PRINT" Playing Simon, either the computer can generate the tune, or a first player."
2010 PRINT"The second player then  tries to  dupli-cate the tune exactly, and if sucessful,";
2020 PRINT"a note is added to the tune.  Use number keys, '1 - 4'.  A black square will"
2030 PRINT"appear above the  correct key to assist you during playing.";
2040 GOSUB400:GOTO41