0 'ESCAPE.100 by Robby DeMarco  2/86
1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
2 'mods by Bill Templeton  6/86
3 CLS:S%=VAL(RIGHT$(TIME$,2)):FORI%=1TOS%:DUMMY=RND(1):NEXTI%:E$=CHR$(27):R$=E$+"p":N$=E$+"q
4 PRINT@94,R$" Escape.100 "N$:PRINT@168,"Do you need instructions?";
5 A$=INKEY$:IFA$=""THEN5
6 IFA$="Y"ORA$="y"THENGOSUB38
7 CLS:FL=0:CALL16959:FORI=0TO39:PRINT@I,CHR$(239):PRINT@I+280,CHR$(239):NEXTI:FORI=0TO319STEP40
8 PRINT@I,CHR$(239):PRINT@I+39,CHR$(239):NEXTI
9 CE=INT(RND(1)*320):IFPEEK(65024+CE)=32THEN9
10 PRINT@CE,CHR$(255):PP=175:PP$=CHR$(144)
11 EC=INT(RND(1)*320):IFPEEK(65024+EC)<>32THEN11
12 PRINT@EC,CHR$(150)
13 IFFL=1THENPRINT@CE,CHR$(224)
14 A$=INKEY$:IFA$=""THENA$="L
15 A=ASC(A$):IFA=28THENPO=1
16 IFA=29THENPO=-1
17 IFA=30THENPO=-40
18 IFA=31THENPO=40
19 PP=PP+PO:IFPEEK(65024+PP)=42THEN33
20 IFPEEK(65024+PP)=239THENPP=PP-PO:PO=-PO
21 IFPEEK(65024+PP)=255THENPP=PP-PO:PO=-PO
22 IFPEEK(65024+PP)=224THEN29
23 IFPEEK(65024+PP)=150THENFL=1
24 C=INT(RND(1)*320):IFPEEK(65024+C)=42THENPRINT@C," ":GOTO28
25 IFPEEK(65024+C)=32THEN27
26 GOTO24
27 PRINT@C,"*";
28 PRINT@PP,PP$:FORI=1TO20:NEXTI:PRINT@PP," ":GOTO13
29 FORI=41TO241STEP40:PRINT@I,STRING$(38," "):NEXT:FORI=0TO10000STEP500:SOUNDI,5:PRINT@95,R$" ESCAPED "N$:NEXTI:GOSUB37
30 IFINKEY$<>""THEN30
31 A$=INKEY$:IFA$=CHR$(13)THENMENUELSEIFA$<>""THEN7
32 GOTO31
33 FORI=3000TO2600STEP-50:PRINT@PP,R$PP$:SOUNDI,5:PRINT@PP,N$PP$:FORC=1TO20:NEXT:NEXTI:SOUND2000,100:GOSUB37
34 IFINKEY$<>""THEN34
35 A$=INKEY$:IFA$=CHR$(13)THENMENUELSEIFA$<>""THEN7
36 GOTO35
37 PRINT@164,"Any key to play, <ENTER> for menu":RETURN
38 GOSUB48
39 PRINT" OBJECT - The object of this game is to  get the key("CHR$(150)") so the locked door("CHR$(255)")    will open";
40 PRINT" and you can leave the arena.  However there are mines(*).  If you     hit one, then you will die.  Use the";
41 PRINT"    arrow keys to move.  You continue":PRINTR$"        Press any key to continue      "N$;
42 A$=INKEY$:IFA$=""THEN42
43 GOSUB48:PRINT" moving in that direction, until you     press another arrow key. Since this is
44 PRINT" a reflex game, don't get frustrated. It may seem impossible at first, but there is a 4 to 1 chance to win.";
45 PRINT" Your chances increase as your reflexes improve.":PRINTR$"        Press any key to continue      "N$;
46 A$=INKEY$:IFA$=""THEN46
47 RETURN
48 CLS:PRINT@0,R$"              Instructions              "N$;:RETURN