0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
50 'MIND.BA, M100 VERSION BY RUSS HALL
60 PRINT:PRINT"    - MASTERMIND GAME -"
70 FOR F=1TOVAL(RIGHT$(TIME$,2)):P=RND(1):NEXT F
80 DIM A$(6),B$(3),C$(3),D$(3),S(3)
85 FOR J=0TO6
90 READ A$(J)
95 NEXT J
100 DATA R,B,G,O,Y,P,S
105 PRINT:PRINT" WHICH VERSION (1 OR 2)?"
110 R$=INKEY$
115 IF R$="1"THENR=1:GOTO130
120 IF R$="2"THENR=2:GOTO130
125 GOTO 110
130 PRINT:PRINT" More than one of same color is legal."
135 PRINT" Colors are Y, G, R, B, O, P,";:IF R=2 THEN PRINT" and S."
140 PRINT"   Be sure 'CAPS LOCK' is down; Space"
142 PRINT" between your choices.
145 FOR T=1TO800:NEXT T:PRINT
240 R=R+5
280 FOR J=0TO3
290 D$(J)=A$(INT(R*RND(J)))
330 NEXT J
350 FOR I=1TO10
355 N=0:M=0
360 PRINT"YOUR CHOICE FOR ROW  ";I;
370 INPUT E$
371 C$(0)=LEFT$(E$,1):C$(1)=MID$(E$,3,1):C$(2)=MID$(E$,5,1):C$(3)=RIGHT$(E$,1)
372 FOR J=0TO3
374 B$(J)=D$(J)
376 NEXT J
380 GOSUB 495
390 IF N<>4 THEN 420
400 PRINT"CONGRADULATIONS! YOU HAVE BROKEN THE    CODE IN"I"ROWS."
410 GOTO 710
420 IF I<10 THEN 470
430 PRINT"CORRECT WAS ";D$(0)" ";D$(1)" ";D$(2)" ";D$(3)
440 GOTO 710
470 NEXT I
495 FOR K1=0TO3
500 IF C$(K1)<>B$(K1)THEN 510
505 N=N+1
510 NEXT K1
515 FOR K1=0TO3
520 FOR K2=0TO3
522 IF K1=K2 THEN 550
525 IF C$(K1)=B$(K1)THEN 550
530 IF C$(K2)=B$(K2)THEN 550
535 IF C$(K1)<>B$(K2)THEN 550
540 M=M+1
545 B$(K2)="X":GOTO 555
550 NEXT K2
555 NEXT K1
590 PRINT"Row"I;N"Black,"M"White"
610 RETURN
710 PRINT"ANOTHER GAME  Y = YES, N = NO";
720 W$=INKEY$:IF W$="N"OR W$="n"THEN MENU
740 IF W$="Y"OR W$="y"THEN GOTO 105 ELSE GOTO 720