0 'MSTRMD.BA TOM HASKINS
1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
10 CLS:LINE (36,0) - (36,56):LINE (101,4) - (101,52):LINE (166,0) - (166,56):LINE (36,17) - (0,17):LINE (36,36) - (0,36):LINE (166,56) - (36,56)
50 X = RND(-VAL(RIGHT$(TIME$,2))):Q = 7
55 FOR A = 1 TO 4
56 N$=MID$(STR$(INT(RND(1)*9)),2) + N$
57 NEXT A
58 PRINT@40,CHR$(27)+"p"+"Choice"+CHR$(27)+"q"
60 L=L+1:N1$=N$
65 PRINT@80,"":INPUT G$:PRINT@120,"      ":IF G$="XXXX" THEN 145 ELSE IF LEN(G$) <> 4 OR ASC(G$) > 57 OR ASC(G$)<48 THEN 65 ELSE G1$ = G$:L1 = L1 + 1:PRINT@ Q + 40*(L-1),G$
70 FOR A = 1 TO 4
75 IF MID$(G1$,A,1)=MID$(N1$,A,1) THEN MID$(N1$,A,1) = "*":MID$(G1$,A,1)="/":C$=C$+CHR$(167)
80 NEXT A
85 FOR A = 1 TO 4:FOR B = 1 TO 4
90 IF MID$(G1$,B,1)=MID$(N1$,A,1) THEN MID$(N1$,A,1)="*":MID$(G1$,B,1)="/":C$=C$+CHR$(157)
95 NEXT B,A
100 C$=C$+STRING$(4-LEN(C$)," "):S$="1234"
105 C = INT(RND(1)*4+1)
110 IF MID$(S$,C,1)="?" THEN 120
115 MID$(S$,C,1)="?":C1$=MID$(C$,C,1)+C1$
120 IF S$ <> "????" THEN 105
125 PRINT @(Q+5)+40*(L-1),C1$:C$="":C1$="":IF L = 7 THEN L = 0:Q = Q + 11
130 IF L1 = 14 AND G$ <> N$ THEN 145 ELSE IF L1 = 14 THEN 140
135 IF G$ <> N$ THEN 60
140 SOUND 4697,5:SOUND 4184,5:SOUND 3728,5:SOUND 3516,5:SOUND 3134,5:SOUND 2793,5:SOUND 2488,5:SOUND 2348,5:PRINT @108,"You guessed":PRINT @148,"it in";L1:PRINT @188,"goes":GOTO 150
145 SOUND 16383,40:PRINT @68,"Nbr was ";N$:PRINT @150,"and you":PRINT @228,"failed in";L1
150 PRINT @280,"Another go (Y/N)?"
155 R$=INKEY$
160 IF R$ = "" THEN 155 ELSE IF R$ = "Y" OR R$ = "y" THEN RUN ELSE MENU