0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
2 'Skydiv, from Tab book of M100 game programs; Wind, 2 player option added by Russ Hall
5 DIMSC(2),TJ(2)
10 CLS:PRINT:PRINTTAB(12)"= =  SKYDIVER  = ="
20 FORN=1TOVAL(RIGHT$(TIME$,2)):T=RND(1):NEXT
30 PRINT:PRINTTAB(14)"Instructions?"
40 PRINT:PRINTTAB(20)"(Y/N)"
50 A$=INKEY$:IFA$=""THEN50
60 IFA$="Y"ORA$="y"THEN140 ELSE GOTO205
140 CLS:PRINT
150 PRINT"     Difficulty level sets size of the"
160 PRINT"landing pad.  Hit any key to jump and"
170 PRINT"release chute. Considering wind and"
180 PRINT"difficulty, you get adjusted points for"
190 PRINT"safe landings and lose five for a crash.";
200 GOSUB1000
205 CLS:PRINT:PRINT"  For 1 player or 2?
206 K$=INKEY$:IFK$=""THEN206
207 IFK$="2"THENNP=2:GOTO210
208 Z=1:GOTO220
210 CLS:IFZ=1THENZ=2 ELSE Z=1
215 PRINT:PRINTTAB(6)"Player #";Z:GOTO221
220 CLS:PRINT
221 C=0
222 W=INT(RND(1)*60)+1'wind
223 W=W-30:IFW>0THENAR$=CHR$(154)
224 IFW<0THENAR$=CHR$(155)
225 PRINTTAB(12)"Wind is"ABS(W)"mph. "AR$
230 PRINT:PRINTTAB(5)"Enter difficulty level:"
240 PRINT:PRINTTAB(4)"[1] Hard to [4] Easy, [Q]uit"
250 A$=INKEY$:IFA$=""THEN250
255 IFA$="Q"ORA$="q"THEN800
260 DF=VAL(A$):FF=VAL(A$)
270 IFDF<1ORDF>4THEN250
275 DF=DF+2:TJ(Z)=TJ(Z)+1'pad size, counter
280 T=INT(RND(1)*10)+292
290 CLS
300 A=1
310 FORN=1TODF'display pad
320 PRINT@T+N,CHR$(239);
330 NEXT
340 PARA$=CHR$(159)
350 PLANE$=CHR$(62)
360 PRINT@28,"Score:";SC(Z);
370 A$=INKEY$
380 PRINT@A,PLANE$;
390 PRINT@A-1,CHR$(32);
400 A=A+1
410 FORN=1TO100:NEXT
420 IFA$=""THEN360
425 REM - Jumped -
430 PRINT@A-1,CHR$(32);
440 PRINT@A,PARA$;
450 FORN=1TO450:NEXT
455 C=(C+.02*W):WC=INT(C+.5)'figure wind into position
460 PRINT@A,CHR$(32);
470 A=A+40+WC
480 IFA>320THENA=A-41:GOTO590'detect miss
490 IFPEEK(A-512)=239THEN510'detect pad hit
500 GOTO440
510 CLS:PRINT
520 PRINTTAB(12)"Nice landing!"
525 FORD=9000TO1000STEP-1000
526 SOUNDD,2:NEXT
529 FF=FF*FF:W=ABS(W):FG=INT(W+21-.33*W-FF)
530 PRINTTAB(12)"You get"FG"points."
550 SC(Z)=SC(Z)+FG
560 GOSUB1000
580 IFNP=2THEN210 ELSE GOTO220
590 FORN=1TO50
600 PRINT@A,CHR$(190);
610 GOSUB730
620 PRINT@A,CHR$(199);
630 NEXTN
640 CLS:PRINT
650 PRINTTAB(12)"You crashed!"
660 PRINT
670 PRINTTAB(12)"You lose five points."
690 SC(Z)=SC(Z)-5
700 GOSUB1000
710 GOTO580
730 SOUND7000,1:RETURN
800 IFNP=2THEN830 ELSE CLS:PRINT:PRINT" You earned"SC(Z)"points from"TJ(Z)"jumps."
810 PRINT:PRINT" Your rating as a skydiver is"INT(SC(Z)/TJ(Z))*4"%"
820 FORN=1TO2000:NEXT:MENU
830 CLS:PRINT:PRINTTAB(5)"Player #1:";SC(1);"points":PRINT:PRINTTAB(5)"Player #2:";SC(2);"points"
840 PRINT:PRINTTAB(5)"From";TJ(1);"jumps.":GOTO820
1000 PRINT:PRINTTAB(11)"==  HIT ANY KEY ==";
1010 A$=INKEY$:IFA$=""THEN1010
1020 RETURN