0 'ZOID.BA - AUTHOR UNKNOWN
1 'CLUB 100 LIBRARY - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
2 ON ERROR GOTO 7002:DIMT%(4,15):D(1)=-1:D(2)=1:D(3)=-40:D(4)=40:MS=279:BOARD=65446:SCRN=65024:TIMER=63791:ESC=27:BARRIER=239:EXTRA=171:EMPTY=32:ENEMY=144:PLAYER=147:GOSUB 6000
3 GOSUB7000:GOSUB2000:GOSUB1000:GOSUB3000:L=160:PRINT@L,CHR$(PLAYER);:PS=100:PRINT@S+1,"Hit Any Arrow Key To Start";:FORZ=1TO11:SOUND T%(4,Z),10:NEXTZ
4 K$=INKEY$:IF LEN(K$)=0 THEN 4
5 PRINT@ MS+1,SPACE$(30);
6 PRINT@L,CHR$(PLAYER);:PRINT@MS," Score: ";:PRINT USING"########";PS;:GOSUB4000:P=PEEK(BOARD):PRINT@ L," ";:IF P<44 OR P>47 THEN PS=PS-10:GOTO6
7 PS=PS+100:D=D(P-43):PK=PEEK(SCRN+L+D):IF PK<>EXTRA THEN9
8 PRINT@MS+1,"Bonus";:PRINT@L+D,CHR$(BARRIER):D=0:PS=PS+50000:FOR Z=1 TO9:SOUND T%(3,2),3:NEXTZ
9 IF PK<49 OR PK>57 THEN11
10 FOR ZZ=1 TO 4:SOUNDT%(4,ZZ),5:NEXTZZ:PRINT@L+D,CHR$(BARRIER);:D=0:PS=PS+1000*(PK-47)
11 IF PEEK(SCRN+L+D)<>EMPTY THEN SOUND500+(P-43)*500,4:D=0:PS=PS-300
12 L=L+D:IF L>MS THEN L=L-MS
13 IF L<1 THEN L=MS+L
14 GOTO6
1000 REM
1001 FORK=1 TO 75:L=INT(RND(1)*MS+1):T=INT(RND(1)*5):IF T<>0 THEN PRINT@L,CHR$(BARRIER);
1002 IFT=0 THEN PRINT@L,CHR$(ESC);"p";CHR$(INT(RND(1)*9+49));CHR$(ESC);"q";
1003 T=INT(RND(1)*50):IF T<NUMBER*2 THENPRINT@L,CHR$(EXTRA);:REM
1004 NEXTK:RETURN
2000 REM
2001 R=PEEK(TIMER)+1:FORI=1TOR:DUMMY=RND(1):NEXTI:RETURN
3000 REM
3001 FORE=1 TO NUMBER:L=INT(RND(1)*MS+1):PRINT@L,CHR$(ENEMY);:L(E)=L:NEXTE:RETURN
4000 REM
4001 Y=INT(L/40):X=L-Y*40:FOR E=1 TO NUMBER:Y2=INT(L(E)/40):X2=L(E)-Y2*40:X2=X2+SGN(X-X2):Y2=Y2+SGN(Y-Y2):NL=Y2*40+X2:IF PEEK(SCRN+NL)=PLAYER THEN 5000
4002 IF PEEK(SCRN+NL)<>EMPTY THENNL=L(E)+D(INT(RND(1)*4+1))
4003 IF NL>MSOR NL<1THEN4005
4004 IF PEEK(SCRN+NL)=EMPTY THEN PRINT@L(E)," ";:L(E)=NL:PRINT@NL,CHR$(ENEMY);
4005 NEXTE:RETURN
5000 REM
5001 PRINT@L(E)," ";:PRINT@NL,CHR$(ENEMY);:FOR I=1TO10:PRINT@NL," ";:SOUND INT(RND(1)*1000+500),3:PRINT@NL,CHR$(ENEMY);:SOUND INT(RND(1)*1000+500),3:NEXTI:FOR ZZ=1TO200:NEXT ZZ:FOR K=1TO6:PRINT@MS+20," You are Dead ";:SOUND T%(1,K*2-1),10
5002 PRINT@MS+20,CHR$(ESC);"p You are Dead ";CHR$(ESC);"q";:SOUND T%(1,K*2),10:NEXTK:IF PS<=HS THEN5005
5003 FOR Z=1TO11:SOUND T%(4,Z),10:NEXTZ:CLS:PRINT:PRINT"Contratulations!":PRINT"You Have Broken The High Score":FOR Z=1TO11:SOUND T%(3,Z),10:NEXTZ:PRINT:INPUT"Please Enter Your Name ";NM$:OPEN"SCORES.do" FOR OUTPUT AS 1:PRINT#1,PS:PRINT#1,NM$:CLOSE1:CLS
5004 PRINT@161,"The Historic Deed Has Been Recorded"
5005 PRINT@1,"  Game Over  ";:PRINT@MS+1,"Hit Space Bar To Play, Enter To Stop";
5006 K$=INKEY$:IF LEN(K$)=0 THEN 5006
5007 IF K$=" "THEN3
5008 IF ASC(K$)=13 THEN CLS:END
5009 GOTO5006
6000 REM
6001 DATA4697,4697,4697,4697,3950,4184,4184,4697,4697,4697,4697,4697:DATA6269,6269,6297,7900:DATA3134,4976,4184,4184,4184,4184,4184,3134,4184:DATA 1567,2348,2092,1864,2092,2348,2092,1864,2348,2348,2348:RESTORE:FOR K=1TO12:READ T%(1,K):NEXTK
6002 FOR K=1TO4:READ T%(2,K):NEXTK:FOR K=1TO9:READ T%(3,K):NEXTK:FOR K=1TO11:READ T%(4,K):NEXTK:RETURN
7000 REM
7001 OPEN"scores.do"FOR INPUT AS 1::INPUT#1,HS:INPUT#1,SC$:CLOSE1:GOTO7003
7002 IF ERR<>52THEN PRINT"error";ERR;"in line";ERL:END:ELSE RESUME7003
7003 CLS:PRINT CHR$(ESC);"pzoid patrol";CHR$(ESC);"q";:IF HS<>0THEN PRINT"high score:";:PRINT USING "########";HS;:PRINT" ";
7004 IF HS=0 THEN PRINT
7005 PRINT USING"\    \";SC$;:REM
7006 PRINT:PRINT"use arrow keys (";CHR$(152);CHR$(153);CHR$(154);CHR$(155);")";:PRINT"to move. to score,";:PRINT"Hit: ";CHR$(ESC);"p1";CHR$(ESC);"q=1000pts ";CHR$(ESC);"p9";:PRINT CHR$(ESC);"q=9000";CHR$(EXTRA);"=50000
7007 PRINT"If Hit: ";CHR$(BARRIER);" Lose 300 Pts. ";:PRINT"The Zoids ( ";CHR$(ENEMY);" )":PRINT "will kill you (";CHR$(PLAYER);")if they catch you!";:PRINT@280,"number of zoids (1-6) 1=easy 6=pro ?";
7008 N$=INKEY$:IF LEN(N$)=0THEN 7008:ELSE NUMBER=VAL(N$)
7009 IF NUMBER<1 OR NUMBER >6 THEN 7008 ELSE PRINT NUMBER;
7010 CLS:RETURN