0 'BIO.BA Richard Hanson
1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
2 CLS:CLS:PRINT"Do you want an explanation of biorhythms <Y>es or <N>o
3 A$=INKEY$:IFA$="Y"ORA$="y"ORA$="N"ORA$="n"THEN4ELSE3
4 DIMO$(70):DIMR(15):DIMT$(12):DIMF(12):DIMJ(2):FORK=1TO8:READT$(K):NEXTK:DATA SUN,MON,TUE,WED,THU,FRI,SAT," ":READK:FORR=1TO12
5 READF(R):NEXTR:DATA 6.283185,31,28,31,30,31,30,31,31,30,31,30,31:CLS:INPUT"What is your name";Z$
6 PRINT"Date format is Month,Day,Year":PRINT"(August 15, 1946 would be 8,15,1946)":INPUT"Birthdate";M1,D1,Y1:M2=M1:D2=D1:Y2=Y1
7 GOSUB32:P1=P2:INPUT"Chart: starting date";M2,D2,Y2:GOSUB32:INPUT"Chart: duration";L:IFA$="Y"ORA$="y"THENGOSUB35
8 X=M1:GOSUB34:J1=J2+Y1*365:IFJ1<639723THENP1=8
9 X=M2:GOSUB34:J2=J2+Y2*365:IFJ2<639723THENP2=8
10 O=J2-J1+4*INT((Y2-Y1)/4-INT((Y2-Y1)/4)):IFY1/4-INT(Y1/4)<>0THEN15
11 IFY2>1THEN14
12 IFM2>2THEN14
13 GOTO15
14 IFM1<3THENO=O+1
15 CLS:PRINT"Biorhythm chart for "Z$:PRINT"Born on "T$(P1)" "M1"/"D1"/"Y1:PRINT"Beginning "T$(P2)" "M2"/"D2"/"Y2
16 PRINT"P = Physical        (23 days)":PRINT"E = Emotional       (28 days)":PRINT"I = Intellectual    (33 days)
17 PRINT"A = Overall Average":FORT=1TO2000:NEXTT:CLS:PRINTTAB(12)"DOWN"TAB(22)"CRITICAL"TAB(37)"UP
18 PRINTTAB(12)"-------------.-------------":IFY2/4-INT(Y2/4)=0THENF(2)=29
19 L=O+L:C=0:FORO=OTOL-1:C=C+1:FORP=0TO26:O$(P)=" ":NEXTP:O$(13)=".":Y=0:X=(SIN(K*(O/23-INT(O/23)))*13.5)+13:O$(X)="P":Y=Y+X
20 X=(SIN(K*(O/33-INT(O/33)))*13.5)+13:O$(X)="I":Y=Y+X:X=(SIN(K*(O/28-INT(O/28)))*13.5)+13:O$(X)="E":Y=(Y+X)/3:O$(Y)="A
21 PRINTT$(P2)TAB(4)M2"/"D2TAB(12);:FORP=0TO26:PRINTO$(P);:NEXTP:PRINT:IFP2=8THEN30
22 P2=P2+1:IFP2>7THENP2=1
23 D2=D2+1:IFD2>F(M2)THEND2=1:M2=M2+1
24 IFM2<13THEN26
25 M2=1:Y2=Y2+1
26 IFY2/4-INT(Y2/4)<>0THEN28
27 F(2)=29:GOTO29
28 F(2)=28
29 NEXTO
30 PRINT:A$="Q":PRINT"Another chart? (<Y>es or <N>o)";
31 A$=INKEY$:IFA$="Y"ORA$="y"THENRUNELSEIFA$="N"ORA$="n"THENMENUELSE31
32 N1=M2+12*INT(.6+1/M2):N2=Y2-INT(.6+1/M2):N3=INT(13*(N1+1)/5):N4=INT(5*N2/4):N5=INT(N2/100):N6=INT(N2/400):N7=N3+N4-N5+N6+D2-1
33 P2=N7-(7*INT(N7/7)):P2=P2+1:RETURN
34 J2=0:FORI=1TOX-1:J2=J2+F(I):NEXTI:RETURN
35 CLS:PRINT"  The biorhythm theory postulates that":PRINT"there are certain metabolic cycles,
36 PRINT"known as inner clocks, which have a":PRINT"constant period in the human body.":PRINT"The three main cycles are a 23 day
37 PRINT"physical cycle, a 28 day emotional":PRINT"cycle, and a 33 day intellectual cycle.":FORT=1TO3000:NEXTT:CLS
38 PRINT"The physical cycle is associated with":PRINT"physical vitality, endurance and":PRINT"energy level.  The emotional cycle
39 PRINT"corresponds to sensitivity, intuition":PRINT" and cheerfulness.  The intellectual
40 PRINT"cycle is related to mental alertness,":PRINT"cognitive power and judgement ability.":FORT=1TO3000:NEXTT:CLS
41 PRINT"  All three cycles start at zero on":PRINT"the upswing at the moment of birth,":PRINT"and continue unbroken throughout a
42 PRINT"person's lifetime.":PRINT"  According to biorhythm theory, the":PRINT"high periods of a cycle are the times
43 PRINT"when a person will probably have the":FORT=1TO3000:NEXTT:CLS:PRINT"most energy, be most cheerful,
44 PRINT"mentally sharp, outgoing and alert.":PRINT"The low period can be regarded":PRINT"as recuperative times, when the body
45 PRINT"is recharging its batteries.  The":PRINT"days on which any cycle crosses the":PRINT"zero line are called *critical days*
46 FORT=1TO3000:NEXTT:CLS:PRINT"and performance may be unstable.":PRINT"  These ideas are presented without
47 PRINT"any statement that they are fact.":PRINT"However, there are thousands who":PRINT"live their lives by their *biorhythm*
48 PRINT"chart.  Here is your chart for your":PRINT"own examination:":FORT=1TO3000:NEXTT:CLS:RETURN