0 'CLUB 100 LIBRARY - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
1 'CompuServe Vidtex Graphics Plotter
2 'Use with MAPPER program, or
3 'Download to USMAP with Telcom
4 '  v.3
5 'By A.B. Trevor, February 1984
6 DEFINT A-Z
7 ON ERROR GOTO36
8 FL$="USMAP"
9 OPEN FL$ FOR INPUT AS 1
10 ON ERROR GOTO0
11 IF EOF(1) THEN PRINT FL$" not a graphics file":STOP
12 IF ASC(INPUT$(1,1))<>27 THEN11
13 CLS:GOSUB32
14 IF A$<>"3"THEN LM=-12 ELSE LM=0
15 T=0:MX=240-LM:A$=INPUT$(2,1):IF A$="GH"THEN SF=256 ELSE IF A$="GM"THEN SF=128:MX=SF:LM=56 ELSE11
16 'Now decode the RLE
17 GOSUB23:X1=X:Y1=Y:GOSUB23:IF B=0THEN17
19 IF X1>=MXTHEN21
20 IFX1>=LM*-1THENIF X<MX AND X>X1 THEN LINE(X1+LM,Y1)-(X+LM,Y1) ELSE LINE(X1+LM,Y1)-(MX+LM-1,Y1)
21 IFLM>=0THENIF Y>Y1 THEN LINE(LM,Y)-(X+LM,Y)
22 GOTO17
23 B=ASC(INPUT$(1,1))-32:X=X+B:IF X>=SF THEN X=X-SF:Y=Y+1:IF Y=64THEN GOSUB26
24 IF EOF(1)THEN GOSUB26
25 RETURN
26 FORS=5000TO999STEP-400:SOUNDS,1:NEXT
27 GOSUB1000
28 T=T+128:IF T>SF THEN CLS:RUN"MAPPER"
29 Y=0:CLS:RETURN
32 ON ERROR GOTO35:FL$="radtim.do":OPEN FL$ FOR INPUT AS 2
33 FORL=1TO3:LINEINPUT#2,A$:PRINTA$:NEXTL:INPUT#2,A$:CLOSE 2
34 ON ERROR GOTO0: RETURN
35 FL$="":RESUME34
36 INPUT"Graphics file to plot";FL$
37 RESUME9
1000 REM EPSON-GEMINI SCREEN DUMP
1009 'Initialize array of print values
1010 IF SX THEN 1020 ELSE DIM SD%(239),SD$(15)
1011 FOR SX=0 TO 15:READ SD:SD$(SX)=CHR$(SD)+CHR$(SD):NEXT SX:E$=CHR$(27)
1019 'Save current cursor position, reset printer, change linefeed length
1020 SC=POS(0):SR=CSRLIN:PRINT E$"P";:FOR SY=0 TO 7
1022 'Move cursor on screen, save one line of data in array SD%(239)
1023 FOR SX=0 TO 39:PRINT@SX+SY*40,;:FOR SZ=-20 TO -15
1024 SD%(SX*6+20+SZ)=PEEK(SZ):NEXT SZ,SX
1026 'Setting graphics mode, print top then bottom half of each line
1027 FOR SW=0 TO 1:LPRINT E$"@"E$"A"CHR$(8)E$"*"CHR$(0)CHR$(224)CHR$(1);
1028 FOR SX=0 TO 239
1029 IF SW THEN LPRINT SD$(SD%(SX)\16); ELSE LPRINT SD$(SD%(SX) MOD 16);
1030 'Return cursor to original posision, and return
1031 NEXT SX:LPRINT:NEXT SW,SY:PRINT@SC+SL*40,"";:RETURN
1040 DATA 255,63,207,15,243,51,195,3, 252,60,204,12,240,48,192,0