0 'PIXEL.BA - AUTHOR UNKNOWN
1 'CLUB 100 LIBRARY - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
10 GOTO510
20 Q$=INKEY$:IFQ$=""THEN70
30 C=INSTR(C$,Q$):IFC=0THEN70
40 IFC>8THEN370
50 ONCGOSUB150,160,170,180,190,200,210,220
60 IFC<9THEN80
70 GOSUB290:GOSUB320:GOTO20
80 IFX<0THENX=X+240
90 IFX>239THENX=X-240
100 IFY<0THENY=Y+64
110 IFY>63THENY=Y-64
120 IFDTHENGOSUB360ELSEGOSUB290:GOSUB350
130 A=X:B=Y:R=T
140 GOTO20
150 X=X+Z:RETURN
160 X=X-Z:RETURN
170 Y=Y-Z:RETURN
180 Y=Y+Z:RETURN
190 X=X-Z:Y=Y-Z:RETURN
200 X=X+Z:Y=Y-Z:RETURN
210 X=X+Z:Y=Y+Z:RETURN
220 X=X-Z:Y=Y+Z:RETURN
230 W=T:D=T:N=6:R=T:PSET(X,Y):RETURN
240 IFDTHENGOSUB360:R=T
250 D=F:N=9:RETURN
260 W=F:D=T:N=12:R=T:PRESET(X,Y):RETURN
270 Z=1:RETURN
280 Z=10:RETURN
290 IFNOTRTHENRETURN
300 PRINT@40*(B\8)+(A\6),C1$;C2$;
310 V=PEEK(CU!+AMOD6):R=F:RETURN
320 M=(M+1)MOD256
330 IFMMODN=0THENPSET(X,Y,(M\N)AND1)
340 RETURN
350 PSET(A,B,SGN(VAND2^(BMOD8))):RETURN
360 PSET(A,B,-W):RETURN
370 IFC=9THEN500:'MENU
380 GOSUB350:IFDTHENGOSUB360
390 PRINT@0,C1$;
400 FORJ=0TO7:Y=J*240:FORI=0TO39:X=I*6
410 PRINT@40*J+I,"";
420 FORZ=0TO5:V=255AND(NOTPEEK(CU!+Z))
430 POKEAD!+X+Y+Z,V
440 NEXT:NEXT:NEXT:BEEP
450 PRINTC2$;:PRINTE$+"W";
460 CLS
470 IF1926+256>FRE(0)THEN PRINT "INSUFFICIENT MEMORY!  SAVE THE ORIGINAL (O) OR REVISED(R) VERSION?":INPUT H$ ELSE 480   :'BEEP:BEEP:PRINT"Insufficient Memory!":END
475 IF H$="O" OR H$="o" THEN 500 ELSE IF H$="R" OR H$="r" THEN 480 ELSE 470
480 FILES:INPUT"Filename";Q$
490 SAVEMQ$,AD!,AD!+1919
500 CLEAR 0,MAXRAM:MENU
510 IF 256+1926>FRE(0) THEN PRINT "Not enough memory to store a picture.":INPUT "Cancel";H$ ELSE 512
511 IF H$="Y" OR H$="y" THEN 500 ELSE 512
512 ' CLEAR256,60982!:POKE61039!,0
520 PRINT"Edit Old Picture (Y/N)? ";:Q$=INPUT$(1)
530 IFQ$<>"Y"ANDQ$<>"y"THEN570
540 CLS:FILES:INPUT"Filename";Q$
550 LOADMQ$
560 POKE61039!,1
570 ' CLEAR256,60982!:DEFINTA-Z:CLS
580 ED=PEEK(61039!)
590 AD!=61040!:CU!=65516!:ML!=60982!
600 E$=CHR$(27):C1$=E$+"P":C2$=E$+"Q"
610 F=0:T=NOTF
620 X=120:Y=32:A=X:B=Y:D=F:N=9:Z=1:R=T
630 C$=CHR$(28)+CHR$(29)+CHR$(30)+CHR$(31)+"p[';"+E$+CHR$(13)
640 FORI=0TO56:READJ:POKEML!+I,J:NEXT
650 PRINT"["+CHR$(154)+"] Right [p] Up-Left    [f.1] Set"
660 PRINT"["+CHR$(155)+"] Left  [[] Up-Right   [f.2] Move"
670 PRINT"["+CHR$(152)+"] Up    ['] Down-Right [f.3] Reset"
680 PRINT"["+CHR$(153)+"] Down  [;] Down-Left  [f.4]  1} Step"
690 PRINTSPACE$(25);"[f.5] 10} Size"
700 PRINT"[ENTER] Save Picture     [ESC] Menu"
710 PRINTE$+"p";" Make Sure CAPS is Unlocked ";E$+"q"
720 PRINT"Hit Any Key to Start";:Q$=INPUT$(1)
730 CLS:PRINTE$+"V";
740 KEY(1)ON:KEY(2)ON:KEY(3)ON:KEY(4)ON:KEY(5)ON
750 ONKEYGOSUB230,240,260,270,280
760 IFED<>1THENBEEP:GOTO20
770 CLS:CALLML!
780 BEEP:GOTO20
790 DATA 033,112,238:REM  LXI  H,61040
800 DATA 017,000,000:REM  LXI  D,0
810 DATA 229        :REMa:PUSH H
820 DATA 213        :REM  PUSH D
830 DATA 006,009    :REM  MVI  B,9
840 DATA 126        :REM  MOV  A,M
850 DATA 005        :REMb:DCR  B
860 DATA 202,089,238:REM  JZ   c:
870 DATA 007        :REM  RLC
880 DATA 210,065,238:REM  JNC  b:
890 DATA 209        :REM  POP  D
900 DATA 213        :REM  PUSH D
910 DATA 245        :REM  PUSH PSW
920 DATA 123        :REM  MOV  A,E
930 DATA 128        :REM  ADD  B
940 DATA 095        :REM  MOV  E,A
950 DATA 029        :REM  DCR  E
960 DATA 197        :REM  PUSH B
970 DATA 205,076,116:REM  CALL PLOT
980 DATA 193        :REM  POP  B
990 DATA 241        :REM  POP  PSW
1000 DATA195,065,238:REM  JMP  b:
1010 DATA209        :REMc:POP  D
1020 DATA225        :REM  POP  H
1030 DATA035        :REM  INX  H
1040 DATA020        :REM  INR  D
1050 DATA122        :REM  MOV  A,D
1060 DATA254,240    :REM  CPI  240
1070 DATA194,060,238:REM  JNZ  a:
1080 DATA022,000    :REM  MVI  D,0
1090 DATA123        :REM  MOV  A,E
1100 DATA198,008    :REM  ADI  8
1110 DATA095        :REM  MOV  E,A
1120 DATA254,064    :REM  CPI  64
1130 DATA194,060,238:REM  JNZ  a:
1140 DATA201        :REM  RET
1150 REM PIXEL 1.0 for the Model 100
1160 REM by William Naoki Kumai