0 ' RGRAPH.BA - BY KEN ZAHORA             Modified for M200 by Steve St.laurent
1 ' Club 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
2 '---RGRAPH.BA--RANDOM GRAPHICS------
3 'THIS PROGRAM DEMONSTRATES SOME OF
4 'THE GRAPHICS CAPABILITIES OF THE
5 'RADIO SHACK MODEL 100.  ANY GRAPHICS
6 'SUBROUTINE LISTED ON THE MENU MAY BE
7 'STARTED BY PRESSING THE INDICATED
8 'KEY.  YOU MAY EXIT A SUBROUTINE AT
9 'ANY TIME BY PRESSING ANY KEY.
10 'ooo MENU ooo
11 CLS:Q=0:PRINT "*** MENU ***":PRINT "1 - RANDOM POINTS":PRINT "2 - RANDOM LINES":PRINT "3 - RANDOM BOXES":PRINT "4 - RANDOM FILLED BOXES":PRINT "5 - RANDOM GRAPHICS":PRINT "6 - END"
12 K$=INKEY$:IF K$="" THEN 12
13 K=ASC(K$)-48:IF K<1 OR K>6 THEN 12
14 ON K GOSUB 19,25,31,37,43,47:GOTO 10
15 'ooo RANDOMIZE ooo
16 K=VAL(RIGHT$(TIME$,2)):FOR I=1 TO K:R%=RND(1):NEXT:BEEP:CLS:RETURN
17 'ooo GET RANDOM VALUES ooo
18 X2=RND(1)*240:Y2=RND(1)*64:X1=RND(1)*240:Y1=RND(1)*128:R%=RND(1)*2:RETURN
19 'ooo PLOT RANDOM POINTS ooo
20 GOSUB 15
21 GOSUB 17:IF R%=0 THEN PRESET(X1,Y1)
22 IF R%=1 THEN PSET(X1,Y1)
23 IF Q=0 THEN K$=INKEY$:IF K$="" THEN 21
24 RETURN
25 'ooo PLOT RANDOM LINES ooo
26 GOSUB 15
27 GOSUB 17:IF R%=0 THEN LINE(X1,Y1)-(X2,Y2),0
28 IF R%=1 THEN LINE(X1,Y1)-(X2,Y2),1
29 IF Q=0 THEN K$=INKEY$:IF K$="" THEN 27
30 RETURN
31 'ooo PLOT RANDOM BOXES ooo
32 GOSUB 15
33 GOSUB 17:IF R%=0 THEN LINE(X1,Y1)-(X2,Y2),0,B
34 IF R%=1 THEN LINE(X1,Y1)-(X2,Y2),1,B
35 IF Q=0 THEN K$=INKEY$:IF K$="" THEN 33
36 RETURN
37 'ooo PLOT RANDOM FILLED BOXES ooo
38 GOSUB 15
39 GOSUB 17:IF R%=0 THEN LINE(X1,Y1)-(X2,Y2),0,BF
40 IF R%=1 THEN LINE(X1,Y1)-(X2,Y2),1,BF
41 IF Q=0 THEN K$=INKEY$:IF K$="" THEN 39
42 RETURN
43 'ooo PLOT RANDOM GRAPHICS ooo        (POINTS, LINES, BOXES & FILLED BOXES)
44 Q=1:GOSUB 15:GOSUB 17
45 R%=RND(1)*4+1:ON R% GOSUB 21,27,33,39:K$=INKEY$:IF K$="" THEN 45
46 Q=0:RETURN
47 MENU