1 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
5 ' Jogging record and Aerobic points
6 ' by Russ Hall
7 ' Thanks to Dr. Kenneth Cooper, TX
10 CLS:LINE(2,6)-(237,61),1,B:LINE(4,8)-(235,59),1,B:PRINT@90,"<A>erobic Points"
40 PRINT@130,"<P>oint Subtotal":PRINT@170,"<T>otal Week Points"
55 PRINT@210,"<G>raph Points":PRINT@250,"<Q>uit";
70 C$=INKEY$:IFC$="A"ORC$="a"THEN150
80 IFC$="Q"ORC$="q"THENMENU
90 IFC$="T"ORC$="t"THEN380
95 IFC$="P"ORC$="p"THEN371
100 IFC$="G"ORC$="g"THEN700
120 GOTO70
150 CLEAR:CLS:PRINT:PRINT" YOU RAN HOW MANY MILES";:INPUTA
170 PRINT" IN HOW MANY MIN/SEC";:INPUTX$
180 Y$=RIGHT$(X$,2):Y=VAL(Y$)/.6
190 Y=CINT(Y):Y=Y/100:Z$=LEFT$(X$,2)
200 Z=VAL(Z$):X=Y+Z:C=X/A:C=CSNG(C)
220 V=(A*60)/X:IFC<10THEN250
240 D=((V-1)*A)-1:GOTO260
250 D=((((2*V)/3)+1)*A)-1
260 D=CINT(D):F=D*22
270 PRINTA"MI. IN"X"MIN. IS WORTH"D"POINTS,   BURNING "F" CALORIES"
280 PRINT"AT AN AVERAGE SPEED OF"C"MIN/MILE"
290 IFC<7THENPRINT"  WOW!!":SOUND1000,20:GOTO320
300 IFC>8THENPRINT"  HO-HUM!":SOUND10000,30:GOTO320
310 PRINT"  GOOD!":SOUND5000,20
320 PRINT"ADD HOW MANY POINTS FOR WALKS";:INPUTE
350 OPEN"RAM:WORK.DO"FORAPPENDAS#1
360 PRINT#1,USING"\      \ ## \ \##.# \\ ##.## \ \ ## \ \";DATE$;A,"mi";X,"mn";C,"avg";D+E,"pts"
370 GOTO10
371 CLEAR:CLS' here for subtotal (doesn't change files)
372 MAXFILES=1:DEFINT T-Z
373 OPEN"RAM:WORK.DO"FOR INPUTAS1
374 E=1:GOTO 430
380 CLEAR:CLS' here for weekend
390 MAXFILES=3
400 DEFINT T-Z
410 OPEN"RAM:RECORD.DO"FOR APPENDAS2
420 OPEN"RAM:WORK.DO"FOR INPUTAS1
430 LINEINPUT#1,A$
440 B$=MID$(A$,10,2)' miles
450 T=T+VAL(B$)
460 C$=MID$(A$,34,2)' points
470 U=U+VAL(C$)
480 D$=MID$(A$,24,5)' averages
490 C=VAL(D$):IFC>8THENC=0:V=V-1' If a walk, don't average in
500 A=A+C:V=V+1
510 IFE=0THENPRINT #2,A$' send to record file
520 IFEOF(1)THENGOTO530 ELSE GOTO430
530 B=A/V
540 B=B*100:B=B+.5
550 B=CINT(B):B=B/100' total average
560 PRINT:PRINT"  TOTAL MLS-"T" PTS-"U" AVG.-"B
565 IFE=1THENFORX=1TO4000:NEXT:GOTO10
570 PRINT#2,"  TOTAL MLS-"T" PTS-"U" AVG-"B
580 OPEN"RAM:MILES.DO"FORINPUTAS3
590 INPUT#3,W' add to miles.do
600 CLOSE1,2,3
610 OPEN"RAM:MILES.DO"FOROUTPUTAS1
620 PRINT#1,W+T
630 FORX=1TO1000:NEXT X
640 KILL"WORK.DO"' Ready for next week
650 GOTO10
700 CLEAR3000:CLS
710 DIMA$(100),C(100)
720 PRINT:PRINT" Name of Record file"
730 LINEINPUT"";F$
740 IFF$=""THENF$="RECORD"
750 OPENF$FORINPUTAS1
760 CLS:PRINT:PRINT" Working..."
770 IFEOF(1)THEN880
780 N=N+1
790 LINEINPUT#1,A$(N)
800 IFLEFT$(A$(N),3)="  T"THEN820
810 GOTO770
820 C(N)=VAL(MID$(A$(N),23,3))
830 IFC(N)<60THENC(N)=60
840 E(T)=C(N)' POINTS
850 B$(T)=LEFT$(A$(N-1),5)' DATE
860 T=T+1:IFT=6THEN880
870 GOTO770
880 CLOSE:CLS
890 FORR=0TOT
900 PRINT@283+R*6,B$(R);:NEXT
910 PRINT@8,"A E R O B I C   P O I N T S"
920 FORY=1TO6
930 PRINT@Y*40,(6-Y)*20+60:NEXT
940 S=30
950 FORR=0TOT-1
960 Q=INT(162-E(R))-.6*(145-E(R))
970 LINE(S,Q)-(S+5,55),1,BF
980 S=S+36:NEXT
990 K$=INKEY$:IFK$=""THEN990
1000 GOTO10