0 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
1 'BIG.BA by Robert Benson (Ver 3.3)
10 CLEAR4400:DIMG$(41),L(40,8),J$(15),M(15),TF$(13),RW(21),RX(21):BE=88:GOTO81
11 CLS:PRINT@56,"BIGPRINT"
12 PRINT@129,"E)nter Bigprint Message"
13 PRINT@169,"S)etup Printer Commands"
14 PRINT@209,"C)hange Block Character"
15 Q$=INKEY$:IFQ$=""GOTO15
16 ONINSTR("EeSsCc",Q$)GOTO18,18,56,56,78,78:Z=PEEK(65451):IFZ=7GOTO17ELSE15
17 IF(INP(187)AND6)<>2THENMENUELSEFORE=1TONP-1:LPRINTCHR$(RX(E));:NEXTE:MENU
18 CLS:PRINT@53,"Printer Width:"
19 PRINT@133,"1)  80 columns"
20 PRINT@213,"2) 132 columns"
21 Q$=INKEY$:IFQ$=""GOTO21ELSEIFQ$="1"THENNC=6ELSEIFQ$="2"THENNC=10ELSE21
22 CLS:PRINT@121,NC"BIG Letters with a max of 12 lines":GOSUB87
23 FORJ=1TO12
24 CLS:PRINT@43,"Line #"MID$(STR$(J),2,2)"  (B)IGPRINT or (S)tandard"
25 TF$(J)=INKEY$:IFTF$(J)=""GOTO25ELSEIFTF$(J)=CHR$(27)THENJ=J-1:GOTO32
26 IFINSTR("BSs",TF$(J))GOTO27ELSE25
27 IFTF$(J)="B"THENZ=PEEK(65442):IFZ<>32THENSOUND1200,3:CLS:PRINT@43,"Depress CAPS/LOCK for BIG letters":GOSUB87:GOTO24
28 PRINTTAB(43):LINEINPUTJ$(J)
29 IFTF$(J)="B"ANDLEN(J$(J))>NCTHENSOUND1200,8:CLS:PRINT@43,"That exceeds"NC"letters, try again":GOSUB87:GOTO24
30 CLS:PRINT@43,"Press the [ESC] key when finished":GOSUB87
31 NEXTJ
32 CLS:PRINT"Your message reads as follows:"
33 FORK=1TOJ
34 PRINT"("TF$(K)")"J$(K)"  ";:NEXT
35 PRINTTAB(80)"Print this message (y/n)?";
36 Q$=INKEY$:IFQ$=""GOTO36ELSEIFQ$<>"Y"ANDQ$<>"y"GOTO11
37 CLS:PRINT"SENDING MESSAGE TO PRINTER...."
38 FORD=1TOCM-1:LPRINTCHR$(RW(D));:NEXTD
39 FORK=1TOJ:IFTF$(K)="B"GOTO44
40 IFTF$(K-1)="B"THENFORU=1TO3:LPRINT:NEXTU
41 LL=LEN(J$(K)):TL=INT((76-LL)/2):LPRINTSTRING$(TL,32)+J$(K)
42 IFTF$(K+1)="B"THENFORU=1TO4:LPRINT:NEXTU
43 GOTO53
44 FORY=1TO8:LL=LEN(J$(K)):TL=LEN(J$(K))*13
45 IFNC=10THENTL=INT((128-TL)/2)ELSEIFNC=6THENTL=INT((78-TL)/2)
46 IFTL<0THENTL=0
47 LPRINTSTRING$(TL,32);:FORV=1TOLEN(J$(K))
48 IFMID$(J$(K),V,1)="0"THENMID$(J$(K),V,1)="O"
49 Z$(V)=MID$(J$(K),V,1):IFV>LEN(J$(K))GOTO53
50 M(V)=ASC(Z$(V))-64:IFM(V)=-32THENM(V)=27:GOTO52
51 IFM(V)<-6ANDM(V)>-16THENM(V)=M(V)+43
52 LPRINTG$(L(M(V),Y))"  ";:NEXTV:LPRINT:NEXTY:LPRINT
53 NEXTK
54 CLS:PRINT@128,"Print another copy (y/n)?"
55 Q$=INKEY$:IFQ$=""GOTO55ELSEIFQ$<>"Y"ANDQ$<>"y"GOTO11ELSE37
56 CLS:PRINT@41,"You may enter up to 20 commands in Dec"
57 PRINT@81,"They should be escape or control codes"
58 PRINT@121,"Hit [ENTER] twice when you're finished"
59 PRINT@212,"Continue (y/n)?"
60 Q$=INKEY$:IFQ$=""GOTO60ELSEIFQ$<>"Y"ANDQ$<>"y"GOTO11
61 CM=1:CLS
62 PRINT"Command #"MID$(STR$(CM),2,2)" ";:LINEINPUTZ$
63 RW(CM)=VAL(Z$):IFRW(CM)=0GOTO65
64 CM=CM+1:GOTO62
65 CLS:PRINT"Here are the commands you just entered:"
66 FORD=1TOCM-1:PRINT"CHR$("MID$(STR$(RW(D)),2,3)") ";:NEXTD
67 PRINTTAB(80)"Is this correct (y/n)?";
68 Q$=INKEY$:IFQ$=""GOTO68ELSEIFQ$<>"Y"ANDQ$<>"y"GOTO61
69 CLS:PRINTTAB(41)"Enter the commands for normal printing":GOSUB87
70 NP=1:CLS
71 PRINT"Command #"MID$(STR$(NP),2,2)" ";:LINEINPUTZ$
72 RX(NP)=VAL(Z$):IFRX(NP)=0GOTO74
73 NP=NP+1:GOTO71
74 CLS:PRINT"These commands restore normal printing:"
75 FORE=1TONP-1:PRINT"CHR$("MID$(STR$(RX(E)),2,3)") ";:NEXTE
76 PRINTTAB(80)"Is this correct (y/n)?";
77 Q$=INKEY$:IFQ$=""GOTO77ELSEIFQ$<>"Y"ANDQ$<>"y"GOTO70ELSE11
78 CLS:PRINT@126,"The defualt character is "CHR$(34)"X"CHR$(34):GOSUB87
79 CLS:PRINT@123,"Input the character of your choice"
80 E$=INKEY$:IFE$=""GOTO80ELSEBE=ASC(E$)
81 CLS:PRINT"ONE MOMENT PLEASE...."
82 FORX=1TO41:READG$(X):IFBE<>88THENGOSUB85
83 NEXTX
84 FORX=1TO36:FORY=1TO8:READL(X,Y):NEXTY:NEXTX:RESTORE:GOTO11
85 FORU=1TOLEN(G$(X)):IFMID$(G$(X),U,1)="X"THENMID$(G$(X),U,1)=CHR$(BE)
86 NEXTU:RETURN
87 FORT=1TO800:NEXTT:RETURN
88 DATA"XXX     XXX","XXXXXXXXXXX","XXXXXXX    "," XXXXXXXXX ","XXXXXXXXXX ","XXX   XXXXX","    XXX    "
89 DATA"XXX  XX XXX","XXX    XXX ","XXX  XXX   ","XXX   XXX  ","XXX    XXXX","XXXX   XXXX","XXX XXX XXX"
90 DATA"XXX  X  XXX","XXXX    XXX","XXXXX   XXX","XXX    XXXX","XXX   XXXXX"," XXXXXXX  X"," XXX   XXX "
91 DATA"  XXX XXX  ","   XXXXX   ","     X     ","  XXXXXXX  ","     XXXXXX","  XXXX     ","   XXX     "
92 DATA" XXXX      ","    XXXX   ","  XXXXX    ","    XXXXXX ","    XXXXXXX","        XXX","XXX        "
93 DATA" XXXXXXXXXX","           ","   XXXX    ","XXXXXXXXX  ","  XXXXX    "," XXXXXXXXXX"
94 DATA4,2,1,1,2,2,1,1,5,2,1,5,2,1,2,5,4,2,35,35,35,35,2,4,5,2,1,1,1,1,2,5,2,2,35,3,3,35,2,2,2,2,35,3,3,35,35,35,36,2
95 DATA35,6,6,1,2,36,1,1,1,2,2,1,1,1,7,7,7,7,7,7,7,7,34,34,34,34,1,1,2,4,9,11,10,3,3,10,11,12,35,35,35,35,35,35,2,2,1
96 DATA13,2,14,15,1,1,1,1,16,17,14,19,18,1,1,4,2,1,1,1,1,2,4,5,2,1,2,5,35,35,35,4,2,1,1,8,1,5,20,5,2,1,5,2,1,1,1,36,2
97 DATA35,5,36,34,2,5,2,2,7,7,7,7,7,7,1,1,1,1,1,1,2,4,1,1,1,21,22,23,7,24,1,1,1,15,14,2,1,1,1,1,21,23,25,21,1,1,1,21,22
98 DATA23,7,7,7,7,2,2,32,30,27,29,2,2,37,37,37,37,37,37,37,37,38,40,7,7,7,7,7,7,5,2,34,4,39,35,2,2,5,2,34,32,33,34,2,5
99 DATA1,1,1,2,2,34,34,34,2,2,35,5,2,34,2,5,35,35,35,5,2,1,2,4,2,2,34,34,34,34,34,34,4,2,1,4,2,1,2,4,4,2,1,2,41,34,2,4