0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
5 'Citizen 120-D formatter-controller
6 'by Russ Hall
20 MAXFILES=2
30 ES$=CHR$(27):D=0:CLS:FILES
50 PRINT:INPUT"Print file (ENTER for prnt ctl)";B$
55 IFB$=""THEN500
60 OPENB$FORINPUTAS1' sizes document
70 ONERRORGOTO120
80 A$=INPUT$(40,1):D=D+1
100 IFEOF(1)THEN130
110 GOTO70
120 RESUME130
130 CLOSE:IFD<73THEN150
141 IFD>94THEND=70:GOTO150
142 Y=INT((95-D)/5):RM=90-Y
144 LPRINTES$"M";' Elite print
146 D=D-15:GOTO170
150 Y=INT((72-D)/5):RM=75-Y
170 LM=Y+5:IFLM=9THENLM=10'  Mine  has  glitch on left margin of 9
180 LF=22-INT(D/3):IFLF<1THEN210
185 IFLF>10THENLF=LF-1
190 FORX=1TOLF:LPRINT:NEXT
210 LPRINTES$"x1"ES$"Q"CHR$(RM);
225 LPRINTES$"l"CHR$(LM)ES$"N"CHR$(8)
232 R$(1)="1380  Diane  Drive":R$(2)="Salt Lake City, UT 84123"'home address
233 R$(3)="P.O. Box 3335":R$(4)="Logan, UT 84321":A=1' work address
240 IFA=5THENLPRINT:LPRINT:GOTO290
242 PRINT"Return address of "R$(A)" ?"
246 K$=INKEY$:IFK$=""THEN246
247 IFK$="Y"ORK$="y"THEN250 ELSE A=A+2:GOTO240
250 LPRINTES$"a";CHR$(2);
260 LPRINTR$(A):LPRINTR$(A+1)
280 LPRINTDAY$".  "DATE$
290 LPRINTES$"a"CHR$(3)
300 OPENB$FORINPUTAS1:OPEN"LPT:"FOROUTPUTAS2
320 IFEOF(1)THEN360
330 A$=INPUT$(1,1):PRINT#2,A$;
350 GOTO320
360 PRINT#2,CHR$(12);
370 CLOSE:MENU
500 CLS:PRINT@3,"PRESS CAPS LOCK...":PRINT@23,"<Q>uit"
510 PRINT@43,"<H>alf LF":PRINT@63,"<D>oublestrike":PRINT@83,"<E>lite":PRINT@103,"<P>roportional"
520 PRINT@123,"<I>talic":PRINT@143,"<R>everse":PRINT@163,"<C>ondensed":PRINT@183,"E<X>panded"
530 PRINT@203,"<V>ert. Enlarged, <O>ff":PRINT@243,"<G>raphics":PRINT@263,"<S>ubscript"
540 PRINT@283,"<T>hree/quarter LF  E<M>phasized";
550 K$=INKEY$:IFK$=""THEN550
560 IFK$="V"THENR$="h"
570 IFK$="E"THENR$="M"
580 IFK$="T"THENR$="0"
590 IFK$="S"THENR$="S1"
600 IFK$="X"THENR$="W1"
610 IFK$="I"THENR$="4"
620 IFK$="H"THENR$="1"
630 IFK$="G"THENR$="m"+CHR$(4)
640 IFK$="O"THENR$="@"
650 IFK$="R"THENR$="r"
660 IFK$="C"THENR$=CHR$(15)
670 IFK$="D"THENR$="G"
680 IFK$="Q"THENMENU
690 IFK$="P"THENR$="p1"
695 IFK$="M"THENR$="E"
700 LPRINTES$R$:GOTO550