0 'AUT100.BA author unknown
1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
10 CLS
20 INPUT "Starting Line Number";S%:PRINT
30 IF S%=0 THEN S%=10
40 INPUT "Increment";I%:PRINT
50 IF I%=0 THEN I%=10
60 INPUT "Program Name";N$
70 N$=N$+".DO"
80 OPEN N$ FOR APPEND AS 1
90 CLS
100 S$=STR$(S%)
110 LN$=RIGHT$(S$,LEN(S$)-1)
120 PRINT LN$+" ";
130 LINE INPUT L$
140 IF L$="" THEN 180 ELSE 150
150 PRINT #1,LN$;" ";L$
160 S%=S%+I%
170 GOTO 100
180 ' *** COMMAND SUBROUTINE ***
190 Y%=CSRLIN:X%=POS(0)
200 IF Y%=7 THEN Y%=6
210 PRINT CHR$(27);CHR$(112);
220 PRINT @ 280,"Cont";
230 PRINT @ 290,"List";
240 PRINT @ 300,"Ins";
250 PRINT @ 305,"LList";
260 PRINT @ 315,"Exit";
270 PRINT CHR$(27);CHR$(113);
280 KEY ON
290 PRINT @ Y%*40+X%,"";
300 ON KEY GOSUB 320,,380,,490,660,,750
310 GOTO 300
320 Y%=CSRLIN:X%=POS(0) '*** CONT ROUTINE ***
330 IF Y%=7 THEN Y%=6 
340 PRINT @ 280,SPACE$(39) 
350 PRINT @ Y%*40+X%,"";
360 KEY OFF
370 GOTO 120
380 CLOSE
390 PRINT @ 280,SPACE$(39) '*** LIST ROUTINE *** 
400 OPEN N$ FOR INPUT AS 1
410 IF EOF(1) THEN 450
420 LINE INPUT #1,LI$
430 PRINT LI$
440 GOTO 410
450 CLOSE
460 OPEN N$ FOR APPEND AS 1
470 GOTO 180
490 Y%=CSRLIN:X%=POS(0) '*** NEW LINE NUMBER INPUT ***
500 IF Y%=7 THEN Y%=6
510 PRINT @ 280,SPACE$(39)
520 PRINT @ Y%*40+X%,"";
530 KEY STOP
540 LINE INPUT L$
550 IF L$="" THEN 180
560 IF INSTR(L$," ")=0 OR LEFT$(L$,1)=" " THEN PRINT "Must enter line number followed by space":GOTO 540
570 IF RIGHT$(L$,1)=" " THEN SY$="BAD":GOTO 640
580 SY$=""
590 LX$=LEFT$(L$,(INSTR(L$," ")-1))
600 FOR I1%=1 TO LEN(LX$)
610	LY$=MID$(LX$,I1%,1)
620	IF NOT (ASC(LY$)>=48 AND ASC(LY$)<=57) THEN SY$="BAD"
630 NEXT I1%
640 IF SY$="BAD" OR VAL(LX$)>65536 THEN PRINT "Invalid Entry":GOTO 540
650 PRINT #1,L$:GOTO 490
660 CLOSE '*** LLIST Routine ***
670 OPEN N$ FOR INPUT AS 1
680 IF EOF(1) THEN 720
690 LINE INPUT #1,LI$
700 LPRINT LI$
710 GOTO 680
720 CLOSE:OPEN N$ FOR APPEND AS 1
730 LPRINT:LPRINT
740 GOTO 180
750 CLOSE:CLS:END '**** EXIT ROUTINE ****