0 ' TLKIT.BA - By Peter Stanwyck 
1 ' Club 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
2 '   1 Kaiser Plaza, Suite 2050
3 '   Oakland, California 94612
4 '  (c)1986  ALL RIGHTS RESERVED
5 CLS:MAXFILES=2:DATE$=LEFT$(DATE$,6)+"86":GOTO29
6 FORA=1TO3000:NEXT:RETURN
7 IFMR=2THENRETURNELSECLOSE:OPENVFORINPUTAS1:RETURN
8 PRINT@280,Z2;Z;Z3;Z1;:RETURN
9 ONERRORGOTO27:PRINT@240,Z1:PRINTZ2;Z;Z3;" Which .DO File "Z1;:V="":PRINT@240,Y3;:INPUTV:IFV=""THEN29ELSEGOSUB7:CLS:RETURN
10 OPEN"TTEM"FOROUTPUTAS2:RETURN
11 PRINT@0,X+SPACE$(255-LEN(X));:RETURN
12 IFINSTR(V,".")=0THENV=V+".do"
13 KILLV:NAME"TTEM.DO"ASV:GOTO29
14 IFEOF(1)THENONMMGOTO12,93,19,87ELSEGOTO17
15 X=STRING$(A,10)
16 MM=3:GOSUB14:B=B+1:C=LEN(X)+C:PRINT@162,Z4;BTAB(20)Y4;C:GOTO16
17 LINEINPUT#1,X:A=INSTR(X,U):G=VAL(LEFT$(X,A)):RETURN
18 GOSUB17:GOTO11
19 B=B-1:IFE2>0THEN34ELSE70
20 C=INSTR(X,"'"):IFC>0THENRETURNELSEC=INSTR(X,U1):IFC=0THENC=256:RETURNELSERETURN
21 Z="Printer Ready"
22 CLS:Q=0:PRINT@240,Z" Y/N ";Z1:X=INPUT$(1):CLS:IFX="y"ORX="Y"THENQ=1ELSEIFQQ<2THEN29ELSERETURN
23 IFQQ=1THENRETURNELSECLS:PRINT@160,"Printing.":RETURN
24 A=INSTR(B,X,U):IFA=0ORA>CTHENRETURNELSED=INSTR(B,X,Z5):IFD=0THEND=256
25 IFA<DTHENX=LEFT$(X,A-1)+MID$(X,A+1):GOTO26ELSED=INSTR(D+1,X,Z5):IFD=0ORD=LEN(X)THENRETURNELSEB=D+1
26 IFM=2THEN24ELSEGOSUB11:GOTO24
27 IFERR=52ORERR=55THENA=0ELSEIFERR=7THENA=1ELSEIFERR=14THENA=2ELSEA=4
28 Z=MID$("File Error Need MemoryNeed StringBad Config Error ??",A*11+1,11):BEEP:CLS:PRINT@200,Z2"** "Z" **"Z3:GOSUB6:GOTO29
29 CLEAR750:GOSUB92:CLS:PRINT@162,"M100 Programming Tool Kit":PRINT@247,"by Peter Stanwyck":PRINT@300,"All Rights Reserved";:CLS:FILES:KEYON:PRINT@280,"ReLn Pack List Fyte RKey Data Csum Menu";:ONKEYGOSUB31,50,55,69,88,82,84,91
30 GOTO30
31 M=1:Z="ReLine":GOSUB9:Y="Don't Renumber"+Z4:Z="<EN>=No Limit":GOSUB8:PRINT@0,X;V:PRINTY"<= ";:INPUTE3:IFE3=0THENE3=-1
32 PRINTY;">= ";:INPUTH1:PRINTZ1:Z="Deflt=x5 at#100":GOSUB8:PRINT@120,"":E1=100:E2=5:INPUT"Increments: ";E2:INPUT"Start Line# ";E1:IFH1=0THENH1=65000
33 IFE1<=E3THENA=3:GOTO28ELSEZ="Ready":QQ=1:GOSUB22:GOSUB16
34 IFFRE(0)-500<CTHENA=2:GOTO28
35 II=E1:DIMG(B),H(B):GOSUB7:FORC=0TOB:GOSUB17:IFG<=E3ORG>=H1THENH=GELSEH=II:II=II+E2
36 PRINT@162,"Old"Z4;GTAB(20)"New"Z4;H:G(C)=(G):H(C)=H:NEXT:CLOSE:GOSUB7:GOSUB10:FORC=0TOB:GOSUB18:X=MID$(STR$(H(C)),2)+MID$(X,A):GOSUB11
37 RESTORE:FORD=1TO7:A=1:READZ:GOSUB8:E=LEN(Z):GOSUB38:NEXT:ONMGOTO49,46
38 L=0:F=INSTR(A,X,Z):IFF=0THENRETURNELSEF=F+E:GOSUB44:IFL=1THENONMGOTO39,73ELSEONMGOTO43,76
39 FORK=0TOB:IFI=G(K)THEN40ELSENEXT:X1="??"+STR$(I):BEEP:GOTO41
40 X1=MID$(STR$(H(K)),2)
41 J=F+LEN(STR$(I))-2:IFJ=LEN(X)THENX2=""ELSEX2=MID$(X,J+1)
42 X=LEFT$(X,F-1)+X1+X2:GOSUB11:J=LEN(X1):GOSUB47:IFLL=1THEN39ELSE43
43 A=F+J:GOTO38
44 I=VAL(MID$(X,F)):IFI>0ORMID$(X,F,1)="0"THENL=1ELSEIFMID$(X,F,2)=" 0"THENL=1:F=F+1
45 IFL=1ANDMID$(X,F,1)=UTHENF=F+1
46 RETURN
47 LL=0:IFMID$(X,F+J,1)<>","THENRETURNELSEF=F+J
48 LL=1:F=F+1:IFMID$(X,F,1)=","THEN48ELSEI=VAL(MID$(X,F)):RETURN
49 PRINT#2,X:NEXT:CLOSE:GOTO12:DATAGOTO,GOSUB,THEN,ELSE,RESUME,RUN,RESTORE
50 Z=U2:GOSUB9:GOSUB10:Z="Delete "+U1:QQ=2:GOSUB22:M=Q
51 MM=1:GOSUB14:Y="":L=0:B=A+1:GOSUB11:GOSUB20:GOSUB24:GOTO52
52 IFC>0ANDM=1THEN54
53 PRINT#2,X:GOTO51
54 IFC<7THEN51ELSEX=LEFT$(X,C-1):GOTO53
55 Z="List":GOSUB9:GOSUB21:GOSUB68
56 C=2:D=1:E=0:F=2:MM=2:GOSUB14
57 J=INSTR(C,X,":"):K=INSTR(C,X,Z5):IFJ=0THEN61ELSEE=1
58 IFK=0ORJ<KTHENY=MID$(X,J):X=LEFT$(X,J-1):GOTO61
59 M=INSTR(K+1,X,Z5):IFM=0THENM=K
60 C=M+1:GOTO57
61 IFD=0THEN62ELSEN=70:B=2:X=LEFT$(X,A)+SPACE$(6-A)+MID$(X,A+1):GOTO63
62 N=64:B=7:IFE=1THENN=59:B=11
63 O=0:IFLEN(X)>NTHENO=1:Z=MID$(X,N+1):X=LEFT$(X,N)
64 LPRINTTAB(B)X:L=L+1:IFL=57THENLPRINTSTRING$(8,13):GOSUB68
65 IFO=0THEN67ELSEX=Z:Z="":IFB=2THENB=8ELSEIFE=1THENX=U+X
66 GOTO63
67 C=2:D=0:X=Y:Y="":IFJ=0THEN56ELSE57
68 P=P+1:LPRINTU;V" As of "DATE$UTIME$U"Page"P:LPRINT:L=2:B=2:RETURN
69 CLEAR1500:GOSUB92:M=2:Z="Fyte":GOSUB9:GOSUB16
70 Y2=": ":BB=B:CC=C:N=B+1:DIMX(N),A(N),G(N):GOSUB7:CLS:PRINTY3;V:PRINTY4;CC:PRINTY7;B:PRINTY6;INT(C/B):PRINTU2;Y2:PRINTU1;Y2:FORE=0TOBB:GOSUB17:G(E)=G:A(E)=LEN(X):PRINT@175,Z4;G;U;A(E)U:
71 GOSUB20:IFC=256THEN72ELSEIFC<7THENR=R+LEN(X):X="X"ELSER=R+LEN(MID$(X,C)):X=LEFT$(X,C-1)
72 B=6:L=LEN(X):GOSUB24:P=P+L-LEN(X):PRINT@165,P;U5:PRINT@204,R;U5:NEXT:GOSUB7:S="     ":FORC=0TOBB:GOSUB17:GOSUB37:NEXT:GOTO77
73 FORK=0TOBB:IFI=G(K)THEN74ELSENEXT:X(N)=X(N)+STR$(I):GOTO75
74 X(K)=X(K)+STR$(G(C))
75 J=LEN(STR$(I))-1:PRINT@175,"From:"G(C);S;S:PRINT@215,"To:";G(K);S
76 GOSUB47:IFLL=1THEN73ELSEA=F+J:GOTO38
77 CLS:GOSUB21:LPRINTTAB(2)Y3;V;U;TIME$;U;DATE$:LPRINT:LPRINTTAB(2)Y4;CC;U;Y7;BB;Y6INT(CC/BB)U;U2;P;U;U1;R:LPRINTTAB(2)"Line"TAB(9)"Bytes"TAB(20)"Branch":LPRINTTAB(2)STRING$(70,"-"):LPRINT:L=6:FORE=0TOBB:IFL>57THENLPRINTSTRING$(66-L,13):L=1
78 LPRINTTAB(2)G(E);TAB(9)A(E);:X=X(E)
79 M=0:IFLEN(X)<56THEN81ELSEM=1:F=55
80 IFMID$(X,F,1)<>UTHENF=F+1:GOTO80ELSEY=MID$(X,F):X=LEFT$(X,F-1)
81 LPRINTTAB(16)X:L=L+1:IFM=1THENX=Y:GOTO79ELSENEXT:IFX(N)<>""THENLPRINT"  UL Errors: "X(N):GOTO93ELSEGOTO93
82 MR=2:Z="Data to":GOSUB9:OPENVFORAPPENDAS1
83 CLS:Z="Enter In "+V:GOSUB8:PRINT@0,"Sgle Entry-<EN> To Rtrn":PRINT:X="":LINEINPUT"Data ";X:IFX=""THEN29ELSEPRINT#1,X:GOTO83
84 Z="CHECKSUM":GOSUB9:CLS
85 MM=4:GOSUB14:E=E+1:IFLEN(X)=0THEN86ELSEFORB=1TOLEN(X):I=I+ASC(MID$(X,B)):NEXT
86 PRINT@162,Z4;E;TAB(15);Z;I:GOTO85
87 Z="Any Key":GOSUB8:X=INPUT$(1):GOTO29
88 CLS:RESTORE90:FORA=1TO8:IFA=6ORA=7THENZ=""ELSEREADZ:IFA=2ORA=3THENZ=Z+CHR$(34)ELSEZ=Z+CHR$(13)
89 KEYA,Z:NEXT:SCREEN0,1:GOSUB6:SCREEN0,0:GOTO29
90 DATAFiles,Load,Save,Run,List,Menu
91 MAXFILES=1:CLEAR256:MENU
92 DEFINTA-F,J-R:DEFSTRS-Z:Z4=" Line#:":Z1=CHR$(27):Z2=Z1+"p":Z3=Z1+"q":Y3="File:":Y4="Size:":Y6="Avr:":Y7="Lines:":Z1=Z1+CHR$(74):U1="REM":U=" ":U4="File":U2="Pack":Z5=CHR$(34):RETURN
93 LPRINTSTRING$(66-L,13):GOTO29