0 'CLUB 100 Library, Modem 415-939-1246
1 'DRCTRY.BA by Paul Globman (C) 1988
2 'Revised 12/26/91 by Lex Jenkins
10 CLS
11 LCD=65024
12 LFILES"ROOT"
13 OPEN"R:DIRLST"FOROUTPUTAS1
14 PRINT#1,"<ROOT DIRECTORY> "DAY$" "DATE$"  "TIME$
15 CLOSE
16 GOSUB30
17 OPEN"R:DIRLST"FORINPUTAS1
18 LINE INPUT#1,D$(1)
19 FORI=1TO10:D$(I)=INPUT$(10,1):NEXT:CLOSE:FORII=1TO10:IFRIGHT$(D$(II),4)<>".<> "THENMENU
20 D$=LEFT$(D$(II),6)
21 KB$="CLS:LFILES"+CHR$(34)+D$+CHR$(34)+":CONT"+CHR$(13)
22 BUF=65451
23 FORJ=1TOLEN(KB$)
24 C=ASC(MID$(KB$,J,1))
25 POKEBUF+(J-1)*2,C
26 POKEBUF+1+(J-1)*2,32
27 NEXTJ
28 POKEBUF-1,LEN(KB$)
29 STOP:PRINT@0,D$:GOSUB30:NEXTII:MENU
30 OPEN"R:/ROOT/DIRLST"FORAPPENDAS1
31 FORI=0TO319
32 PRINT#1,CHR$(PEEK(LCD+I));
33 NEXTI
34 CALL23164,0,23366:CALL27795
35 CLOSE
36 RETURN
40 'GOSUB 30 captures the LCD and appends it to DIRLST.DO.
41 'Lines 10-16 display ROOT dir and puts it in DIRLST.DO.
42 'Lines 17-19 reads DIRLST.DO and builds an array of directory names.
43 'Lines 19-29 executes for each directory poke into keyboard buffer a
44 'CLS;LFILES "dir" and CONT.
45 'The STOP allows  the keyboard buffer to execute,
46 'then continues by APPENDing current LCD display to DIRLST.
47 'Line 34 restores function keys to their default settings.