10 CLS:CLEAR2000:MAXFILES=2:KEY(8)ON:ONKEYGOSUB,,,,,,,390:RV$=CHR$(27)+"p":NV$=CHR$(27)+"q"
11 DEFSTRA,B,D:DEFINTC,F,L-P,T-V,Y:GOSUB210:AB=CHR$(9):AR=CHR$(13)
12 AC=AB+AR+CHR$(255)+CHR$(167)+CHR$(154)+CHR$(155)+CHR$(246)+CHR$(247):BB="":V=1:PL=0:N=0:GOSUB300
13 FORLL=0TO9:T(LL)=LM+((LL+1)*10):NEXT:GOTO40
14 FORLL=0TO9:IF(LM+N)<T(LL)THENM=T(LL)-(LM+N):B=B+SPACE$(M+1):N=N+M:RETURN
15 NEXT:RETURN
16 AA=""
17 IFEOF(1)THEN380ELSEA=INPUT$(1,1)
18 IFINSTR(AC,A)>0ORA=","THEN20
19 AA=AA+A:GOTO17
20 LL=VAL(AA):RETURN
40 OPENF$FORINPUTAS1
50 OPEN"COM:38N1E"FOROUTPUTAS2
60 PRINT@206,V;
70 IFEOF(1)THEN380ELSEA=INPUT$(1,1)
86 IFA=CHR$(167)THENGOSUB400:GOTO86
87 IFA=CHR$(154)THENGOSUB16:IFLL>LMTHENRM=LL:GOTO86ELSE86
88 IFA=CHR$(155)THENGOSUB16:IFLL<RMTHENLM=LL:GOTO86ELSE86
89 IFA=CHR$(255)THENFL=1:GOTO70
90 IFA=CHR$(129)THENGOSUB16:IFLL<5ORLL>60THEN86ELSEL=LL:GOTO86
93 IFFL=0THENIFB=""ANDA<>ARTHENB=SPACE$(LM)
94 IFA=CHR$(246)THENB=B+CHR$(27)+"E":GOTO175
95 IFA=CHR$(247)THENB=B+CHR$(27)+"R":GOTO175
100 IFA=CHR$(153)THENB=B+STRING$(L-PL-1,AR):PL=PL+(L-PL-1):A=AR
130 IFA=ABTHENGOSUB14:GOTO150
140 IFC=1ANDA=" "THEN175ELSEC=0:Y=Y+1:N=N+1:B=B+A
145 IFFL=0ANDA>CHR$(13)THENIFA<>" "THENPSET(151+LM+N,2+PL)
150 IF(N+LM=>RM-6)AND(A=" "ORA=AB)THENA=AR:B=B+A+CHR$(10):FL=0:C=1
160 IFFL=1ANDA=ARTHENML=((RM-LM-1)-N)/2:BB=BB+SPACE$(ML+LM):FL=0:LINE(151+ML+LM,2+PL)-(151+ML+LM+N-1,2+PL)
170 IFA=ARTHENBB=BB+B:PL=PL+1:N=0:PRINT@246,PL;:B=""
174 IFB=""AND(DS="Y"ORDS="y")THENBB=BB+AR:PL=PL+1
175 IF(LEN(BB)+LEN(B))<160ANDPL<LTHEN70
176 PRINT#2,BB;
179 BB=""
180 IFPN$="Y"ORPN$="y"THENAA="PAGE"+STR$(V):LL=LEN(AA):ML=((RM-LM-1)-LL)/2:BB=BB+AR+SPACE$(ML+LM)+AA:AA="":PRINT#2,BB:BB=""
190 IFPL=>LTHENPRINT#2,:GOTO360
200 GOTO70
210 CLS:PRINT@160,"Do you want documentation (Y/N)? ";:A=INPUT$(1):IFA="N"ORA="n"THENRETURN
211 IFA<>"Y"ANDA<>"y"THENBEEP:BEEP:GOTO210
215 CLS:ML=0
220 PRINTSPACE$(9)RV$" FORMAT CONTROL CODES"NV$:PRINT
230 READM,LL,AA:IFM=99THENIFML>0THEN290ELSERETURN
240 IFM=0THENPRINTRV$;"<GRPH>";NV$;" `";MID$(AA,1,1);"' ";
250 IFM=1THENPRINTRV$;"<CODE>";NV$;" `";MID$(AA,1,1);"' ";
260 IFM=4THENPRINTRV$;"<TAB>";NV$;"      ";
265 IFM=5THENPRINTAA;
270 IFLL<>0THENPRINTCHR$(LL);
275 IFM=5THEN230
280 IFM<2ORM>3THENPRINT" ";MID$(AA,2)
285 IFM=2THENPRINTAAELSEIFM=3THENPRINTRV$;AA;NV$
286 ML=ML+1:IFML<5THEN230
290 PRINT"Press "RV$" ENTER "NV$" to continue ";:A=INPUT$(1):IFM=99THENRETURNELSE215
300 CLS:INPUT"NAME OF FILE TO BE FORMATTED:";F$
310 LM=10:PRINT"LEFT MARGIN SET AT"LM;:INPUTLM:IFLM<0ORLM>79THENBEEP:BEEP:GOTO310
320 RM=75:PRINT"RIGHT MARGIN SET AT"RM;:INPUTRM:IFRM<LMORRM>80THENBEEP:BEEP:GOTO320
330 L=55:PRINT"PAGE LENGTH SET AT:"L;:INPUTL:IFL<3ORL>60THENBEEP:BEEP:GOTO330
332 PRINT"PAGE NUM: N";:PN$=INPUT$(1):PRINT@170,PN$;
335 PRINT@173,"DOUBLE SPACE: N";:DS=INPUT$(1):PRINT@187,DS
340 CLS:LINE(149,0)-(236,63),1,B
345 PRINT@200,"PAGE#";:PRINT@240,"LINE#";
350 RETURN
360 IFEOF(1)THENPN$="":GOTO380
370 BEEP:PRINT@280,"INSERT NEW PAGE <ENTER>";:DU$=INPUT$(1):PRINT@280,STRING$(24," ");:V=V+1:PL=0
372 CLS:LINE(149,0)-(236,63),1,B:PRINT@200,"PAGE#";:PRINT@240,"LINE#";:GOTO60
380 IFB<>""THENBB=BB+B:PL=PL+1
381 IFBB<>""THENPRINT#2,BB;:BB=""
382 IFPN$="Y"ORPN$="y"THENIFPL<>0THENBB=STRING$(L-PL,AR):PL=L:GOTO180
385 PRINTY"ltrs":PRINTRV$"<ENTER>"NV$;:BEEP:DU$=INPUT$(1)
389 PRINT#2,CHR$(13):CLOSE:PRINT:PRINTRV$" PRINTING COMPLETE."NV$V"PAGES ";
390 MAXFILES=0:MENU
400 M=0:FORLL=0TO9:T(LL)=0:NEXT
410 GOSUB16:IFLL<LMORLL>RMTHEN430
420 T(M)=LL:M=M+1
430 IFA<>","THENRETURN
440 IFM<=9THEN410ELSERETURN
500 DATA2,0,"<<Print Formatter for Brother EP 44>>",2,0,"<<By Richard Helman 70536,1061>>"
510 DATA2,0,"<<Modified by William Hart 75745,1545>>",2,0," ",2,0," ",3,0," EP 44  Settings: "
520 DATA2,0,">baud=300    >bit length=8   >parity=N",2,0,">line=CR+LF  >code=T/W       >er=Y"
530 DATA2,0," ",2,0," ",0,255,"CLine Centering",0,246,"MUnderline start",0,247,">Underline stop"
540 DATA0,155,"lSet LEFT margin",0,154,"kSet RIGHT margin",1,167,"_Set TAB stops",0,153,",End of page"
550 DATA0,129,"mSet page length (5-60)",4,0,"  Tab to preset stop",2,0," "
555 DATA5,155,"Follow ",5,154,", ",5,167," and ",2,0," with column #(s)."
560 DATA5,167,"Separate up to 10 stops by `,' after ",2,0," "
565 DATA5,27,"end by another code or ",5,27,"p<CR>",2,0,"q."
570 DATA5,27,"NOTE:  All ",5,27,"p<CR>",2,0,"q's generate a newline."
575 DATA5,27,"",5,27,"p F8 ",2,0,"q will return to MENU at any time"
580 DATA99,0," "