1 CLS:DATE$=LEFT$(DATE$,7)+"6":GOTO2
2 PRINT"     ***** MASTER MENU *****"
3 PRINT"1 = Set up dot matrix printer."
4 PRINT"2 = Enter Interactive Solutions."
5 PRINT"3 = Copy Data Mgr. file(-s)."
6 PRINT"4 = Clear space for files."
7 PRINT"5 = MORE..."
8 INPUT"MAKE SELECTION";X
9 IFX=1THEN15
10 IFX=2THEN27
11 IFX=3THEN30
12 IFX=4THEN37
13 IFX>4THEN38
14 IFX<1THENMENU
15 CLS:PRINT"PRINTER SET MENU (PICK 1)"
16 PRINT"     1=NLQ, 10 PI"
17 PRINT"     2=small print, reg."
18 PRINT"     3=NLQ, small type"
19 PRINT"     4=WIDE PRINTING"
20 PRINT"     5=Draft printing"
21 PRINT:INPUT"CHOICE ";B
22 IFB=1THENLPRINTCHR$(27);CHR$(31)
23 IFB=2THENLPRINTCHR$(27);CHR$(23)
24 IFB=3THENLPRINTCHR$(27);CHR$(31);CHR$(27);CHR$(23)
25 IFB=4THENLPRINTCHR$(27);CHR$(14)
26 PRINT"DONE...":END
27 CLEAR1000,60200
28 CALL63012
29 END
30 FILES:MAXFILES=2
31 INPUT"Copy FROM";Y$
32 INPUT"Copy TO";Z$
33 OPENX$FORINPUTAS1
34 OPENZ$FOROUTPUTAS2
35 PRINT#2,INPUT$(1,1);
36 IFEOF(1)THENCLOSE1,2:PRINT"DONE!":END
37 CLEAR256,MAXRAM:END
38 CLS:PRINT"MASTER MENU - PAGE TWO"
39 PRINT"6. VERIFY tape save"
40 PRINT"7. SORT a file"
41 PRINT"8. GLOBAL SEARCH/REPLACE"
42 PRINT"9. TFND a file"
43 PRINT"0. FIGURE LOAN PAYMENT"
44 PRINT"1. RETURN TO PAGE 1"
45 INPUT"MAKE SELECTION";Y
46 IFY=6THEN52
47 IFY=7THEN84
48 IFY=8THEN94
49 IFY=9THEN127
50 IFY=0THEN135
51 IFY<6THEN1
52 MAXFILES=2
53 CLEAR100
54 ONERRORGOTO78
55 FCB=64668
56 SND=65348
57 CLS
58 PRINT
59 PRINT"Push 'PLAY'"
60 PRINT"Searching cassette for .DO file..."
61 OPEN"cas:"FORINPUTAS1
62 CLS:PRINT"Found: CAS:";
63 F$=""
64 FORJ=FCBTOFCB+5
65 P=PEEK(J)
66 IFP<>32THENF$=F$+CHR$(P)
67 NEXT
68 PRINTF$;".DO"
69 GOSUB77
70 OPENF$FORINPUTAS2
71 PRINT"Found: RAM:";F$;".DO"
72 GOSUB77
73 PRINT:PRINT:CLS:PRINT"Verifying..."
74 IFEOF(1)OREOF(2)THEN75ELSEIFINPUT$(1,1)=INPUT$(1,2)THEN74ELSECLOSE:PRINT"FILES DO NOT MATCH...VERIFY FAILS!":GOTO82
75 IFEOF(1)ANDEOF(2)THENPRINT"VERIFY SUCCESSFUL!":GOSUB77:ENDELSEPRINT"FILES NOT SAME LENGTH...VERIFY FAILS!":GOTO82
76 IFPEEK(SND)THENRETURNELSESOUND15000,80:RETURN
77 IFPEEK(SND)THENRETURNELSEFORI=5TO8:SOUND5000/I,10:NEXT:RETURN
78 IFERR=52THENRESUME79ELSEIFERR=18THENRESUME81ELSEONERRORGOTO52
79 PRINT"RAM File ";F$;".DO NOT found!"
80 GOTO82
81 PRINT"Tape I/O ERROR! Try again."
82 GOSUB76
83 END
84 CLS
85 CLEARFRE(0)-999:FILES:MAXFILES=1:INPUT"File";N$:OPENN$FORINPUTAS1
86 LINEINPUT#1,Q$:X=X+1:IFNOTEOF(1)THEN86
87 CLOSE:DIMA$(X):X=0:OPENN$FORINPUTAS1
88 X=X+1:LINEINPUT#1,A$(X):IFNOTEOF(1)THEN88
89 PRINTX;"records":CLOSE:W=2^INT(LOG(X))-1
90 FORI=1TOX-W:FORV=ITO1STEP-W:IFA$(V)<=A$(V+W)THEN92
91 Q$=A$(V):A$(V)=A$(V+W):A$(V+W)=Q$:NEXT
92 NEXTI:W=INT(W/2):IFW>0THEN90
93 KILLN$:OPENN$FOROUTPUTAS1:FORY=1TOX:PRINT#1,A$(Y):NEXT:CLOSE:CLEAR0:BEEP:END
94 SCREEN,0:CLEAR2000:MAXFILES=2:DEFINTA-Z:DEFSTRM-Z
95 M=CHR$(8):N=CHR$(27):O=CHR$(34):P=N+"p":Q=N+"q":U=" Replace ":V=" Delete ":ONERRORGOTO124
96 CLS:FILES:PRINT:INPUT"Name of .DO file";X:IFX=""THENEND
97 IFINSTR(X,".")=0THENX=X+".DO"
98 Y="O.DO":Z="T.DO":NAMEX$ASY
99 PRINT" "T;:CLS:PRINTI+1;M":"U"what? ";:LINEINPUTS(I):IFS(I)=""THENIFI=0GOTO123ELSE107
100 PRINT@160,I+1;M":"U"it with? ";:LINEINPUTR(I):IFR(I)=""THENPRINT@181,P;M;V"?"Q;ELSE102
101 T=INKEY$:IFT="N"ORT="n"THENPRINTN"l":GOTO100ELSEIFT="Y"ORT="y"THEND(I)=1ELSE101
102 B=I:PRINT@280,P"Selective";:IFD(I)THENPRINTV;ELSEPRINTU;
103 PRINTM;"?";Q;" ";
104 T=INKEY$:IFT="Y"ORT="y"THENF(I)=1ELSEIFT<>"N"ANDT<>"n"THEN104
105 PRINTT;" ";:IFI<9THENPRINTP" Another?"Q;ELSE107
106 T=INKEY$:IFT="Y"ORT="y"THENI=I+1:GOTO99ELSEIFT<>"N"ANDT<>"n"THEN106
107 PRINT" "T;:CLS
108 FORI=0TOB:OPENYFORINPUTAS1:OPENZFOROUTPUTAS2:L=LEN(S(I))
109 IFEOF(1)THEN121
110 LINEINPUT#1,W:E=LEN(W)
111 PRINT@53,P;I+1;M":";:IFD(I)THENPRINTV;ELSEPRINTU;
112 PRINTO;S(I);O;Q;
113 J=INSTR(1,W,S(I)):IFJ=0THEN119ELSEC(I)=1
114 K=LEN(W):R=R(I):IFF(I)THENCLS:PRINTLEFT$(W,J-1);P;S(I);Q;RIGHT$(W,K-(J+L-1))ELSE118
115 IFD(I)THENPRINT@282,P;V"?"Q;ELSEPRINT@282,P;U"with ";O;R;O"?"Q;
116 T=INKEY$:IFT="N"ORT="n"THENR=S(I)ELSEIFT<>"Y"ANDT<>"y"THEN116
117 CLS
118 PRINT#2,LEFT$(W,J-1);R;:W=MID$(W,J+LEN(S(I))):GOTO111
119 IFE=255THENPRINT#2,W;ELSEPRINT#2,W
120 GOTO109
121 CLOSE:IFC(I)=0THENPRINTP":No ";S(I);" in ";X;Q;:GOSUB126
122 KILLY:NAMEZ$ASY:NEXT
123 NAMEY$ASX:END
124 IFERR=52THENPRINTP"No file ";X;Q;:GOSUB126:X="":RESUME96ELSECLS:BEEP:PRINT@53,P"Aborted: Error"ERR"in "ERL
125 GOSUB126:CLOSE:KILLZ:GOTO123
126 FORA=1TO999:NEXT:RETURN
127 MAXFILES=2:CLEAR900
128 OPEN"NEWFIL.DO"FORAPPENDAS2
129 CLS:FILES:INPUT"input file:";F$:CLS:PRINT:INPUT"TFND: ";SS$
130 OPENF$FORINPUTAS1
131 IFEOF(1)THENCLS:CLOSE:END
132 LINEINPUT#1,A$
133 IFINSTR(A$,SS$)THEN134ELSE131
134 PRINT#2,A$:GOTO131
135 PRINT:PRINT:INPUT"AMOUNT";X:INPUT"YEARS";Y:INPUT"INTEREST";Z:Z=Z/1200:PRINTUSING"$$###.##";X/((1-1/(1+Z)^(12*Y))/Z)