100 CLS:PRINT:PRINT "          OPEN CHANNEL DESIGN"
105 PRINT "              Version 1.0"
110 PRINT "      (c) 1989 Gary L. Van Balen"
115 PRINT "          All Rights Reserved"
120 PRINT "     Distribution By Permission Only"
125 PRINT "    Contact Author on CIS [71500,611]"
130 FOR T=0 TO 2000:NEXT
135 PF$="ON"
140 CLS
145 REM MAIN MENU
150 PRINT
155 PRINT "      P)rint Results (";PF$;")"
160 PRINT "      N)ew Ditch"
165 PRINT "      F)low Parameter Mod."
170 PRINT "      C)onfiguration of Ditch Mod."
175 PRINT
180 PRINT "      Enter Selection (Q to Quit):";
185 F$=INKEY$:IF F$="" THEN 185
190 IF F$="Q" OR F$="q" THEN MENU
195 IF F$="N" OR F$="n" THEN 220
200 IF F$="F" OR F$="f" THEN 220
205 IF F$="C" OR F$="c" THEN 275
210 IF F$="P" OR F$="p" THEN PF$="OFF"
215 GOTO 140
220 CLS
225 REM ENTER FLOW PARAMETERS
230 PRINT"***  ENTER FLOW PARAMETERS  ***"
235 PRINT
240 PRINT"Design flow in CFS";
245 INPUT FLOW
250 PRINT"Mannings Roughness Coefficient";
255 INPUT ROUGH
260 PRINT"Hydraulic Slope in decimal form";
265 INPUT SP
270 IF F$="F" OR F$="f" THEN 415
275 REM ENTER CONFIGURATION
280 CLS
285 RS=0
290 LS=0
295 WITH=0
300 BS=0
305 PRINT"***  ENTER DITCH CONFIGURATION  ***"
310 PRINT
315 PRINT"Ditch RT side slope (?H:1V), H =";
320 INPUT SR
325 RS = 1/SR
330 PRINT"Ditch LT side slope (?H:1V), H =";
335 INPUT SL
340 LS = 1/SL
345 PRINT"Ditch bottom width";
350 INPUT WITH
355 PRINT
360 IF WITH=0 THEN SBS=1:GOTO 415
365 PRINT"Bottom of ditch sloped to one side"
370 PRINT"or is it level (S/L)";
375 INPUT A$
380 IF A$="S" THEN GOTO 405
385 IF A$="s" THEN GOTO 405
390 IF A$="L" THEN SBS=1:GOTO 415
395 IF A$="l" THEN SBS=1:GOTO 415
400 GOTO 365
405 PRINT"Slope of bottom in decimal form";
410 INPUT BS
415 REM ROUND OFF DESIGN FLOW
420 FLOW=(INT(100*(.005+FLOW)))/100
425 CLS:PRINT@80,"Half Interval Search for Q In Progress"
430 REM CALCULATE FLOW BASED ON 'D'
435 L1=0
440 L2=0
445 L4=0
450 I=1
455 D=.1
460 IN=1
465 AREA=0
470 PRINT @178,I
475 I=I+1
480 IF SBS=1 GOTO 490:ZL=LS:LS=RS: RS=ZL
485 REM TO RESTORE RS & LS BEFORE PRINTING
490 IF D<BS*WITH GOTO 510
495 AREA=D^2/(LS*2)+(BS*WITH^2)/2+(D-BS*WITH)*WITH+(((D-BS*WITH)/RS)*(D-BS*WITH))/2
500 WP=((D/LS)^2+DE^2)^.5+((BS*WITH)^2+WITH^2)^.5+((D-BS*WITH)^2+((D-BS*WITH)/RS)^2)^.5
505 GOTO 520
510 AREA=D^2/(LS*2)+D^2/(BS*2)
515 WP=((D/LS)^2+D^2)^.5+(D^2+(D/BS)^2)^.5
520 Q=(INT(((.005+((1.486/ROUGH)*AREA*(AREA/WP)^(2/3)*SP^.5))*100)))/100
525 REM CHECK IF CALCULATED FLOW EQUALS DESIGN FLOW
530 REM
535 IF Q=FLOW GOTO 565
540 REM IF CALCULATED FLOW IS EQUAL TO THE DESIGN FLOW, THEN DEPTH OF DITCH IS OK: THEREFORE PRINT ANSWERS
545 IF Q<FLOW THEN D=D+IN:GOTO 470
550 REM IF CALCULATED FLOW IS LESS THAN DESIGN FLOW, THEN INCREASE THE DEPTH BY 'IN' AND RECALCULATE FLOW
555 IF Q>FLOW THEN IN=IN/2:D=D-IN:GOTO 470
560 REM IF CALC. FLOW IS > DESIGN FLOW, THEN CUT IN HALF AND DECREASE THE DEPTH BY THE NEW 'IN', AND RECALC. FLOW
565 REM OUTPUT ANSWERS
570 CLS
575 VLCTY=(INT(100*((Q/AREA)+.005)))/100
580 FRBOARD=(INT(100*(.005+(1+(.025*Q/AREA)*D^.3333))))/100
585 Q=(INT(100*(.005+Q)))/100
590 D=(INT(100*(.005+D)))/100
595 REM Show results on screen
600 CLS:PRINT"***  DESIGN FLOW PARAMETERS  ***"
605 PRINT
610 PRINT"Design flow in CFS";FLOW
615 PRINT"Mannings Roughness Coefficient";ROUGH
620 PRINT"Hydraulic Slope";SP
625 PRINT
630 PRINT "Any Key to continue:";
635 P$=INKEY$:IF P$="" THEN 635
640 CLS
645 PRINT"***  DITCH CONFIGURATION  ***"
650 PRINT
655 HRS=1/RS
660 HLS=1/LS
665 PRINT"RT SIDE SLOPE =";HRS;"H:1V"
670 PRINT"LT SIDE SLOPE =";HLS;"H:1V"
675 PRINT"BOTTOM WIDTH  =";WITH;"FT"
680 IF WITH=0 GOTO 695
685 SB = BS*100
690 PRINT"CROSS SLOPE   =";SB;"%"
695 PRINT
700 PRINT "Any Key to continue:";
705 P$=INKEY$:IF P$="" THEN 705
710 CLS
715 PRINT"***  CALCULATED RESULTS  ***"
720 PRINT
725 PRINT"Calculated Flow =";Q;"cfs"
730 PRINT"Depth, d = ";
735 PRINT USING "#####.##";D;
740 PRINT " ft"
745 PRINT"Area of Flow, A =";
750 PRINT USING "#####.##";AREA;
755 PRINT " SQ FT"
760 PRINT
765 PRINT "Any Key to for more:";
770 P$=INKEY$:IF P$="" THEN 770
775 CLS
780 PRINT"Wetted Perimeter, WP =";
785 PRINT USING "#####.##";WP;
790 PRINT " FT"
795 PRINT"Velocity, V =";VLCTY;"fps"
800 PRINT"Freeboard =";FRBOARD;"ft"
805 TD=D+FRBOARD
810 PRINT
815 PRINT"TOTAL REQUIRED DEPTH =";TD;"FT"
820 PRINT
825 PRINT "Any Key to continue:";
830 P$=INKEY$:IF P$="" THEN 830
835 IF PF$="ON" THEN 140
840 CLS
845 REM Make hard copy
850 CLS:PRINT"Press Any Key after turning on printer.";
855 P$=INKEY$:IF P$="" THEN 855
860 LPRINT"***  DESIGN FLOW PARAMETERS  ***"
865 LPRINT
870 LPRINT"Design flow, Q = ";FLOW;"cfs"
875 LPRINT"Mannings Roughness Coefficient";ROUGH
880 LPRINT"Hydraulic Slope, S = ";EPOLS;"%"
885 LPRINT
890 LPRINT "***   DITCH CONFIGURATION   ***"
895 LPRINT
900 HRS=1/RS
905 HLS=1/LS
910 LPRINT "RT Side Slope = ";HRS;"H:1V"
915 LPRINT "LT Side Slope = ";HLS;"H:1V"
920 LPRINT
925 LPRINT "Width of Bottom = ";WITH;"FT"
930 IF WITH=0 GOTO 940
935 LPRINT "Cross Slope of Bottom = ";SB;"%"
940 LPRINT
945 LPRINT "***   CALCULATED RESULTS   ***"
950 LPRINT
955 LPRINT "Calculated Flow = ";Q;"cfs"
960 LPRINT "Depth = ";D;"ft"
965 LPRINT "Area of Flow, A =";
970 LPRINT USING "#####.##";AREA;
975 LPRINT " SQ FT"
980 LPRINT "Wetted Perimeter, WP =";
985 LPRINT USING "#####.##";WP;
990 LPRINT " ft"
995 LPRINT "Velocity of Flow, V = ";VLCTY;"fps"
1000 LPRINT
1005 LPRINT "Freeboard = ";FRBOARD;"ft"
1010 TD=D+FRBOARD
1015 LPRINT
1020 LPRINT "TOTAL REQUIRED DEPTH = ";TD;"FT":LPRINT:LPRINT
1025 GOTO 140