100 'EMBED
110 'A.R.Jacobs
120 'Bagdad
130 'Arizona
140 '86321
150 'Create a file MATRIX.DO with the 
160 'puzzle matrix.
170 'Create a file EMWORD.DO with the
180 'words which are hidden in the matrix.
190 'The program will create a file
200 'called EMOUT.DO containing the
210 'result which is also printed.
220 CLEAR3000:DEFINTA-Z:MAXFILES=3:DIMMT$(50,50),WO$(50)
230 CLS:PRINT@125,"The Program Is Running."
240 OPEN"MATRIX.DO"FORINPUTAS1
250 OPEN"EMOUT.DO"FOROUTPUTAS2
260 FORH=1TO100:LINEINPUT#1,LN$:FORI=1TOLEN(LN$):MT$(H,I)=MID$(LN$,I,1):NEXTI
270 IFEOF(1)THENCLOSE#1:GOTO290
280 NEXTH
290 OPEN"EMWORD.DO"FORINPUTAS1:C=1
300 LINEINPUT#1,LN$:WO$(C)=LN$:C=C+1:IFEOF(1)THEN310ELSE300
310 CLOSE#1
320 LPRINT"EMBEDDED              HORIZONTAL            VERTICAL              DIRECTION"
330 LPRINT"  WORDS               COORDINATE           COORDINATE              OF WORD"
340 LPRINT"________              __________           __________             _________"
350 OPEN"MATRIX.DO"FORINPUTAS1
360 FORH=1TO100:LINEINPUT#1,LN$:IFEOF(1)THENCLOSE#1ELSENEXTH
370 W=LEN(LN$)
380 OPEN"EMWORD.DO"FORINPUTAS1
390 FORL=1TO100:LINEINPUT#1,LN$:IFEOF(1)THENCLOSE#1ELSENEXTL
400 FORK=1TOL:LT$=LEFT$(WO$(K),1)
410 FORI=1TOH:FORJ=1TOW:IFLT$=MT$(I,J)THENX=J:Y=I:GOTO450
420 NEXTJ:NEXTI
430 NEXTK
440 CLOSE#2:MENU
450 FORD=1TO8
460 LN$=""
470 FORLN=1TOLEN(WO$(K))
480 IFX<1ORX>WORY<1ORY>HTHEN510
490 IFMT$(Y,X)<>MID$(WO$(K),LN,1)THEN530
500 LN$=LN$+MT$(Y,X)
510 ONDGOSUB580,590,600,610,620,630,640,650
520 IFLN$=WO$(K)THENGOTO660
530 NEXTLN
540 LN$=""
550 X=J:Y=I
560 NEXTD
570 GOTO420
580 Y=Y+1:DI$="S":RETURN
590 X=X-1:Y=Y+1:DI$="SW":RETURN
600 X=X-1:DI$="W":RETURN
610 X=X-1:Y=Y-1:DI$="NW":RETURN
620 Y=Y-1:DI$="N":RETURN
630 X=X+1:Y=Y-1:DI$="NE":RETURN
640 X=X+1:DI$="E":RETURN
650 X=X+1:Y=Y+1:DI$="SE":RETURN
660 LPRINTUSING"\                  \      ##                   ##                     \\";WO$(K),J,I,DI$
670 PRINT#2,WO$(K);J;I;DI$
680 LPRINT:GOTO430