10 'Draw Poker 1.1 by Karl Chase, [70536,253]
11 'Albuquerque, New Mexico, April 1984
100 GOSUB750
110 GOSUB2110
140 FORH5=5TO0STEP-1:H=H5*5:GOSUB570:GOSUB410:IFH5<5THENGOSUB818
145 NEXT:H=0:H5=0:LS$=S$:GOSUB590
150 DL=DL+1:IFDL>5THENDL=0
160 PRINT@55+40*DL,"d";
170 FORI=0TO5:AC(I)=1:B(I)=0:BF(I)=0:BT(I)=0:NEXT:PH=1:FD=0:PL=DL:GOSUB270
180 IFAN=300THENGOSUB782:CLS:PRINT@44,"NO OPENERS":GOTO110
185 IFFD=5THEN110
190 GOSUB590
200 PRINT@55+40*DL,"d";
210 FORH6=DL+1TODL+6:H5=H6MOD6:H=H5*5:IFH<>0THEN220
215 PRINT@120,"DISCARDS ?":PRINT@160,"("LS$")":GOSUB600:GOSUB800:GOSUB590
217 PRINT@120,B$:PRINT@160,B$:PRINT@80,B$:GOTO230
220 IFAC(H5)=0THEN240ELSEGOSUB410:GOSUB610
230 GOSUB570:GOSUB490
240 NEXT:FORI=0TO5:PRINT@58+I*40,"   ";:NEXT
245 FORI=0TO5:B(I)=0:BT(I)=0:NEXT:MB=10:PH=2:PL=OP-1:PRINT@56+40*OP,"o";:GOSUB270
250 CLS:FORH5=0TO5:H=H5*5:IFFD=5THENGOSUB590:GOTO110ELSEIFH=0ORAC(H5)><0THENGOSUB590:GOSUB730
260 NEXT:GOTO110
270 V=0:BN=-1:MB=0:RZ=0
280 PL=PL+1:P1=PLMOD6:PRINT@23,"$ TO CALL  "MB-BT(P1):P=VL(P1):IFAN=300AND(P<159ORP\50=4)THENBN=BN+1:GOTO390
290 IFAC(P1)=0THENB(P1)=0:GOTO390
300 IFP1>0THEN310ELSEPRINT@63,"WHAT BET";B$:PRINT@71,"";
305 FORI=1TO4:SOUND11000,5:SOUND15000,5:NEXT:INPUTS$:GOSUB1250:B0=VAL(S$):GOTO320
310 ONPHGOSUB1300,1500
320 V=VAL(S$):IFP1>0THENV=((RND(1)*60+V)\10)*10:GOTO328
322 RK=SK-MB+BT(0):IFRK<0THENV=0:S$="F"
324 IFV>RKTHENV=RK
328 IFV>200THENV=200
330 IFRZ>3ANDV>0THENS$="C"
340 IFAN=300ANDS$="C"THENBN=BN+1:GOTO390
350 IFS$="C"THENB(P1)=MB-BT(P1):BT(P1)=BT(P1)+B(P1):BN=BN+1:SOUND3000,9:GOTO380
360 IFS$="F"THENAC(P1)=0:FD=FD+1:B(P1)=0:SOUND9000,10:SOUND 15000,15:GOTO390
370 SOUND1000,5:SOUND700,5:SOUND1000,5:B(P1)=V+MB-BT(P1):BN=0:BT(P1)=BT(P1)+B(P1):RZ=RZ+1
380 AN=AN+B(P1):MB=BT(P1):IFP1=0THENSK=SK-B(0)
390 PRINT@57+40*P1,"";:IFAC(P1)=0THENPRINT" F  ";ELSEIFS$="C"THENPRINT" C  ";ELSEPRINTV
400 GOSUB800:IFFD+BN>4THENRETURNELSE280
410 GOSUB 490:S$=L$
412 VZ=VL(H5):IFVZ>160THENRETURN
414 IFVZ<159ORRND(1)*9>WB(H5)THEN420
416 S$=MID$(S$,3,1):BF(H5)=1:IFRND(1)>.5THENS$=""
418 RETURN
420 IFC(H)MOD4=C(H+1)MOD4ORC(H)MOD4=C(H+2)MOD4THENC0=C(H)MOD4ELSEC0=C(H+1)MOD4
430 RK=0:L$="":FORI=0TO4:IFC(H+I)MOD4=C0THENRK=RK+1:J=IELSEL$=L$+CHR$(I+49)
440 NEXT:IFRK=4THENS$=L$:VL(H5)=200+C(J)\4:GOTO480
450 C1=C(H+1)\4:IFC(H+2)\4<>C1+1ORC(H+3)\4<>C1+2THEN480
460 IFC1-1=C(H)\4THENS$="5":VL(H5)=200+C(H+3)\4:GOTO480
470 IFC1=C(H+4)\4-3THENS$="1":VL(H5)=200+C(H+4)\4
480 IF(S$="1"ORS$="5")ANDRND(1)*9<WB(H5)THENBF(H5)=1
485 RETURN
490 GOSUB 630
500 C1=C(H)MOD4:FORI=1TO4:IFC(H+I)MOD4<>C1THEN510ELSENEXT:VL(H5)=400+C(H+4)\4:L$=""
510 C1=C(H)\4:CS=C(H+4):IFC1=0ANDCS>47THEN:C(H+4)=16
515 FORI=1TO4:IFC(H+I)\4<>C1+ITHEN530ELSENEXT
520 L$="":IFVL(H5)>400THENVL(H5)=VL(H5)+100ELSEVL(H5)=350+CS\4
530 C(H+4)=CS
535 IFVL(H5)<250ANDPH=2ANDRND(1)*9<WB(H5)THENBF(H5)=1
537 RETURN
550 RETURN
560 PRINT@44,"DEALING":FORI=0TOE:C(I)=I:NEXT:FORI=0TOE:J=RND(1)*52:K=C(I):C(I)=C(J):C(J)=K:NEXT
569 RETURN
570 FORI=HTOH+3:FORJ=I+1TOH+4:IFC(I)>C(J)THENK=C(I):C(I)=C(J):C(J)=K
580 NEXT:NEXT:RETURN
590 PRINT@H5*40+40,"";:FORI=HTOH+4::S=C(I)MOD4+156:S$=CHR$(S):V=C(I)\4:V$=F$(V):PRINTV$;S$;" ";:NEXT:RETURN
600 PRINT@307,"OKAY DRAW ";:PRINT@80,"";:S$="":INPUTS$:GOSUB1250:LQ=LEN(S$)
610 LN=LEN(S$):PRINT@62+H5*40,LN;
615 IFLN=0THENRETURN
617 FORI=1TOLN:L=ASC(MID$(S$,I,1))-49:IFL<0ORL>4THEN600ELSEL1=L1-1:C(L+H)=C(L1):NEXT:GOSUB570
620 RETURN
630 RK=0:VL(H5)=C(H+4)\4
640 A(0)=C(H)\4=C(H+1)\4:FORI=1TO3:A(I)=C(I+H)\4=C(I+H+1)\4ORC(I+H)\4=C(I+H-1)\4:NEXT:A(4)=C(H+4)\4=C(H+3)\4:L$=""
650 CS=0:FORI=0TO4:IFA(I)=0THENL$=L$+CHR$(I+49):GOTO670ELSEC0=C(H+I)\4:CS=CS+C0:VL(H5)=C0:RK=RK+1
660 SF=C0:C1=C0:VL(H5)=C0+RK*100
670 NEXT:VR=VL(H5)\100:IFVR=2THENVL(H5)=VL(H5)-50
680 IFVR<>4THEN700ELSEIFCS=C0*4THENVD=100ELSEVD=-150
690 VL(H5)=VL(H5)+VD
700 IFVR=5THENVL(H5)=VL(H5)-150ELSE720
710 IFC0<>C(H+2)\4THENVL(H5)=VL(H5)-C0+C(H)\4
720 IFLEN(L$)=2THENL$=RIGHT$(L$,1)
725 IFVL(H5)\50=7THENVL(H5)=VL(H5)+100
726 RETURN
730 C0=VL(H5)\50:C1=VL(H5)MOD50
740 PRINT@H5*40+60,MID$(F1$,C1+1,1)+"  "+N$(C0);:RETURN
750 DEFINTA-Z:B$="          ":CLS:PRINT@44,"PLEASE WAIT";:E=51:SK=2000:HB=1
755 DIMC(E),N$(15),F$(12):F1$="23456789TJQKA":FORI=1TO13:F$(I-1)=MID$(F1$,I,1):NEXT
757 N9=-1745:FORH5=PEEK(N9)TO128:GOSUB802:NEXT:
760 FORI=0TO5:WB(I)=RND(1)*5+1:NEXT:FORI=0TO11:READN$(I):NEXT:RETURN
770 DATAHigh,X,X,'s,X,Up,Trips,Str't,Flush,Full,Fours,St Flush
780 FORI=1TO1000:NEXT:RETURN
782 FORI=1TO3000:NEXT:RETURN
800 PRINT@230,"CASH";SK;:PRINT@271,"POT";AN;:RETURN
802 FORI=PEEK(N9+1)TO13:H9=RND(1):NEXT:RETURN
818 FORI=1TO6:SOUND11000,1:FORH8=0TO193:NEXT:NEXT:RETURN
1250 IFLEN(S$)=0THEN1260ELSEIFASC(MID$(S$,1))>96THENS$=CHR$(ASC(MID$(S$,1))-32)
1260 GOSUB802:RETURN
1300 MC=MB-BT(P1):IFAN>300THEN1340
1310 S$="C":IFP>158THENS$="10":OP=P1
1320 IFP>258ORBF(H5)=1THENS$="75":OP=P1
1330 RETURN
1335 IFBF(H5)>0THENP=258
1340 IFHB>1THENMC=MC-50*HB
1345 IFFD+BN=4ANDP<250ANDP>158ANDMC<50THENS$="C":RETURN
1350 IFP<161THENS$="F":RETURN
1360 IFP<250THEN1370
1365 S$="C":IFMC<100ORRND(1)<.2THENS$="40"
1367 RETURN
1370 IFMC<60ORRND(1)<.1*WB(H5)THENS$="C"ELSES$="F"
1380 RETURN
1500 IFBF(H5)>0THENBF(H5)=0:P=355
1505 MC=MB-BT(P1)-P\5
1510 IFHB>1THENMC=MC-50*HB
1520 IFLQ=0THENMC=MC+40
1530 IFP<300THEN1580
1535 IFLQ>2THENMC=MC-80
1537 IFMC>140ANDP<258THEN1610
1540 IFMC<90THENS=50+P\10:S$=CHR$(S)+"1":RETURNELSE1610
1580 IFLQ>2THENMC=MC-40
1590 IFMB>0ANDP<160THEN1620
1600 IFMC>40THEN1620
1610 S$="C":RETURN
1620 IF(P>250ANDRND(1)*10<WB(H5))OR(P>160ANDRND(1)*17<WB(H5))THEN1610ELSES$="F":RETURN
2000 CLS:PRINT:PRINT:PRINT"You are flat broke"
2010 PRINT"Want to play again  Y/N "
2020 S$=INKEY$:IFS$=""THEN2020ELSEIFS$="y"ORS$="Y"THENRUNELSEEND
2110 IFAN=300THENAN=-PEEK(63791):FORI=ANTO0:L1=RND(1):NEXT:SK=SK+50:GOTO2140
2120 GOSUB782:GOSUB800:IFAN<1THEN2140ELSEIFAC(0)=0THEN2128
2122 FORI=1TO5:IFAC(I)<>0ANDVL(I)>VL(0)THEN2128
2124 NEXT:SK=SK+AN:PRINT@289,"YOU WON!!";:FORI=1200TO400STEP-200:SOUNDI,5:NEXT:SOUND1200,10:SOUND1000,13
2125 IFB0>99ANDFD=5THENHB=HB+1
2126 IFFD<5ANDVL(0)>160THENHB=HB-1
2127 GOTO2136
2128 PRINT@289,"SORRY YOU LOST";:SOUND3000,60:SOUND6000,60:IFSK<0THEN2000
2130 IFAC(0)=0ORB0<49THEN2140ELSEIFVL(0)<161THENHB=HB+1ELSEHB=HB-1
2136 IFHB>4THENHB=4ELSEIFHB<0THENHB=0
2140 GOSUB782:L1=52:AN=300:SK=SK-50:CLS:GOSUB800:GOSUB 560:IFSK<0THEN2000ELSERETURN:PRINT"