1 REM (C) Creative Computing
2 REM Rewritten for TRS-80 PC-2 by David Dunn Thomas April 1983
3 REM Spinning effect May 1983
4 REM Rewritten for Model 100 by Dave Thomas August 1983 - revised 12/7/83
5 CLEAR:DEFSTRA-N:DEFINTW-Z:A3=SPACE$(3):A6=SPACE$(6):A7=SPACE$(7):K=CHR$(27)+CHR$(75):B1=CHR$(245):B2=CHR$(123)
6 E1=CHR$(45):E2=CHR$(128):E3=CHR$(129):E4=CHR$(132):E5=CHR$(171):E6=CHR$(176):E9="Now try to collect your winnings!"
7 B3=CHR$(125):C=CHR$(27)+CHR$(112):D=CHR$(27)+CHR$(113):B=B2+CHR$(66)+E1+CHR$(65)+E1+CHR$(82)+B3:J=C+B
8 L=">SLOTS<":G=B2+E4+B1+E4+B1+E4+B3:H=B2+E5+B1+E5+B1+E5+B3
9 I=B2+E2+B1+E2+B1+E2+B3:E=B2+E3+B1+E3+B1+E3+B3
15 F=B2+E6+B1+E6+B1+E6+B3:GOTO33
16 FORS1=1TO2:PRINT@120,A7;B;A3;G;A3;H;: SOUND2000,2:GOSUB30:PRINT@120,K;:GOSUB 30:PRINT@120,A7;E;A3;F;A3;B;:SOUND1000,2
17 GOSUB30:PRINT@120,K;:GOSUB30:PRINT@ 120,A7;G;A3;H;A3;I;:SOUND 2000,2:GOSUB 30:PRINT@120,K;:GOSUB30
24 PRINT@120,A7;H;A3;I;A3;E;:SOUND1000, 2:GOSUB30:PRINT@120,K;:GOSUB30: PRINT@ 120,A7;I;A3;E;A3;F;:SOUND2000,2:GOSUB30
25 PRINT@120,K;:GOSUB30:PRINT@120,A7;F; A3;B;A3;G;:SOUND 1000,2:GOSUB30:NEXT
30 FORT1=1TO50:NEXT:RETURN
31 SOUND4000,5:SOUND3500,5:SOUND3000,5: RETURN
32 SOUND3500,5:SOUND3000,5:SOUND2500,5: RETURN
33 CLS:PRINT@120,A7;L;A3;J;D;A3;L:P=0: S=0
34 PRINT@203,"Your bet <O>ne, <T>wo, or <F>ive ?";:BEEP:BEEP
36 M=INKEY$:IFM=""THEN36ELSEIFM=CHR$(27)THEN76ELSEIFM="O"ORM="T"ORM="F"THEN40ELSE36
40 S=S+1:IFP>9999THENO=1000:T=2000: Q=5000ELSEO=100:T=200:Q=500
43 V=Q:IFM="O"THENV=O:ELSEIFM="T"THENV=T
46 CLS:GOSUB116:GOSUB16:FORT1=1TOVAL(RIGHT$(TIME$,2))+2:T#=RND(1):NEXT:X=RND(1)*6+1:Y=RND(1)*6+1:Z=RND(1)*6+1
49 PRINT@120,A7;:ONXGOSUB98,99,100,101, 102,103:GOSUB31:GOTO55
55 PRINTA3;:ONYGOSUB98,99,100,101, 102,103:GOSUB32
61 PRINTA3;:ONZGOSUB98,99,100,101, 102,103
67 IFX=YTHEN80ELSEIFX=ZTHEN83
69 IFY=Z THEN85
70 PRINT@40,"YOU LOST!":U=U+1:SOUND8000, 5:SOUND11000,5:P=P-V
71 PRINT"Your bankroll is now: ";:PRINTUSING"$$#######,";P
72 IFP<100000THEN34ELSESOUND3500,5: SOUND1000,10:PRINT@160,K"GET OUT OF HERE!!!":SOUND3000,5:SOUND500,10
74 PRINTK"You broke the bank!!":FORT1=1TO2000:NEXT:GOTO87
76 IFP<0THENE9="Pay up! Put your money HERE!!!":goto87ELSEIFP=0THENE9="HEY! You broke even!":goto87
77IFP<100001THEN87ELSE118
80 IFY=ZTHEN90ELSEIFY=1THEN95ELSE117
83 IFZ=1THEN95ELSE69
85 IFZ=1THEN95ELSE117
87 BEEP:CLS:PRINT@40,E9:BEEP:GOTO118
90 IFZ=1THEN93
91 V1=10:E7="** TOP DOLLAR **":GOSUB31: GOSUB111:GOSUB31:GOTO96
93 V1=100:E7="*** JACKPOT ***":GOSUB31:GOSUB32:GOSUB111:GOSUB31:GOSUB32:GOTO96
95 V1=5:E7="* DOUBLE BAR *":GOSUB32: GOSUB111:GOSUB31
96 P=(((V1*V)+V)+P):GOTO71
98 PRINTJ;D;:RETURN
99 PRINTG;:RETURN
100 PRINTH;:RETURN
101 PRINTI;:RETURN
102 PRINTE;:RETURN
103 PRINTF;:RETURN
111 PRINT@53,E7:W=W+1:RETURN
116 SOUND2000,2:SOUND1500,2:SOUND2500,2: RETURN
117 GOSUB31:PRINT@52,"DOUBLE! YOU WON!":W=W+1:P=(((2*V)+V)+P):GOTO71
118 PRINT:PRINT"You enjoyed"S" fine spins.":PRINT"You won: "W" and you lost: "U:PRINT"Winning: "INT(W/S*100)"%"
119 FORT1=1TO2000:NEXT:CLS:PRINT@120, "The time is now "C;TIME$;D:PRINT"Do you know "C"where"D" you are?"
120 FORT1=1TO2000:NEXT:MENU