1 REM: typ CAT TRAP.100/DES for game instructions
5 GOSUB3500
10 GOSUB900:CLS:GOSUB2000:X=121:Y=140:D=1:R=4:GOSUB990:E=RN
20 LINE(6,27)-(10,27):LINE(8,25)-(10,27):LINE(8,29)-(10,27)
30 A=PEEK(65430):B=PEEK(65431)
37 FORR=1TO30:NEXTR
40 IF(BAND8)=8THEND=-40
50 IF(BAND4)=4THEND=40
60 IF(BAND2)=2THEND=1
70 IF(AAND8)=8THEND=-1
90 X=X+D
100 IFX<0ORX>318THENX=FX
105 IFPEEK(X+65024)<>32THEN1000
110 IFD=1THENX$=CHR$(154)ELSEIFD=-1THENX$=CHR$(155)
120 IFD=40THENX$=CHR$(153)ELSEIFD=-40THENX$=CHR$(152)
130 PRINT@X,X$;:GOSUB3000:GOTO30
900 R=VAL(RIGHT$(TIME$,2)):FORCO=1TOR:A=RND(1):NEXT:RETURN
990 RN=INT(RND(1)*R+1):RETURN
1000 L=L+1:FORR=1TO25:PRINT@X,CHR$(27)"p"CHR$(255);:PRINT@X,CHR$(27)"q"CHR$(255);:SOUND10000,1:NEXT
1010 CLS:PRINT:PRINT:PRINT"You have been smashed up into pieces!!"
1020 SOUND2000,5:SOUND3000,3:SOUND3500,10
1030 PRINT:PRINT"Wins:"W;"    Losses:"L
1040 INPUT"Play again";Q$:Q$=LEFT$(Q$,1):IFQ$="N"ORQ$="n"THENMENUELSE10
1500 W=W+1:FORR=1TO25:PRINT@Y,CHR$(27);"p"CHR$(145);:PRINT@Y,CHR$(27)"q"CHR$(145);:SOUND10000,1:NEXT
1510 CLS:PRINT:PRINT:PRINT"Ah hah!! You have won!! The enemy has":PRINT"been smashed to pieces!!"
1520 SOUND3500,5:SOUND3000,3:SOUND2000,10
1530 GOTO1030
2000 PRINT@0,STRING$(39,CHR$(239));
2010 FORR=0TO6:PRINT@R*40,CHR$(239);:PRINT@R*40+38,CHR$(239);:NEXT:PRINT@280,STRING$(39,CHR$(239));:RETURN
3000 FE=E:FY=Y:DS=DS-1:IFDS<0THENR=10:GOSUB990:DS=RNELSE3100
3010 R=4:GOSUB990
3020 E=RN
3025 IFFE=E+2ORFE=E-2THENE=FE
3030 IFE=1THENDI=-40
3040 IFE=2THENDI=1
3050 IFE=3THENDI=40
3060 IFE=4THENDI=-1
3100 R=5:GOSUB990:Y=Y+DI:P=PEEK(Y+65024)
3105 IFP>151ANDP<156ORP=145ANDRN=1THEN1500ELSEIFP<>32THENDS=0:Y=FY
3110 IFY<0ORY>318THENY=FY
3120 PRINT@Y,CHR$(145);:RETURN
3500 CLS:PRINT:PRINTTAB(10)"--trapper--"
3510 PRINT:PRINT"by Dave Cloutier...":PRINT:PRINT"Inspired by the movie "CHR$(34)"TRON"CHR$(34)
3520 PRINT:PRINT"(Press <ENTER> to begin)";
3530 IFINKEY$<>CHR$(13)THEN3530ELSERETURN