0 'CHGMNU.BA MENU Util. for 100/102/200  READ CHGMNU.DOC first! R.Hess 7/13/88, 72367,552
2 BEEP:BEEP:GOSUB92:PRINT@120,"HAVE YOU READ THE INSTRUCTIONS?! Y/N ";:Q$=INPUT$(1)
4 IFINSTR("Yy",Q$)=0THENBEEP:MENU
6 CLEAR:P=80:GOSUB92:PRINT@120,"<C>hange or <R>estore MENU references? ";:M$=INPUT$(1)
8 IFINSTR("Cc",M$)THEN28ELSEIFINSTR("Rr",M$)=0THENMENU
10 IFPEEK(1)<>171THEN20
12 P$="TEXT  ":L=62045:A=29085:GOSUB76
14 P$="TELCOM":L=62056:A=24573:GOSUB76
16 P$="ADDRSS":L=62067:A=28391:GOSUB76
18 P$="SCHEDL":L=62078:A=28397:GOSUB76:MENU
20 P$="TEXT  ":L=63853:A=24046:GOSUB76
22 P$="TELCOM":L=63864:A=20806:GOSUB76
24 P$="ADDRSS":L=63875:A=23400:GOSUB76
26 P$="SCHEDL":L=63886:A=23407:GOSUB76:MENU
28 GOSUB92:PRINT@122,"<C>hange MENU  <V>isiblity on MENU ";:GOSUB80
30 IFINSTR("Vv",Q$)THENGOSUB92:PRINT@81,"Change which MENU listing's visiblity? ":GOSUB82:GOSUB80:GOSUB50:POKEL,PEEK(L)XOR8:GOTO6
32 IFINSTR("Cc",Q$)=0THEN6
34 GOSUB92:PRINT@86,"Change which MENU location?":PRINT:GOSUB82:GOSUB80:GOSUB50
36 GOSUB92:PRINT@P+7,"Old name is: "O$:PRINT"New name (6 char.)";:LINEINPUT"? ";P$
38 IFP$=""THENBEEP:GOTO6ELSEIFLEN(P$)<>6THENBEEP:GOTO36
40 PRINT"  CALL "P$" at: ";:AA=A:INPUTA:IFA=0THENA=AA
42 GOSUB92:PRINT@P,"Change MENU reference for: "O$:PRINT@128,"to MENU reference: "P$
44 PRINT@167,"which is CALLed at:"A
46 PRINT:PRINT@251,"Is this OK? Y/N ";:Q$=INPUT$(1):IFINSTR("Yy",Q$)=0THEN6
48 GOSUB76:GOTO6
50 IFPEEK(1)<>171THEN64
52 IFINSTR("Tt",Q$)THENL=62045:A=29085
54 IFINSTR("Ee",Q$)THENL=62056:A=24573
56 IFINSTR("Aa",Q$)THENL=62067:A=28391
58 IFINSTR("Ss",Q$)THENL=62078:A=28397
60 IFLTHENGOSUB96:RETURN
62 BEEP:GOTO28
64 IFINSTR("Tt",Q$)THENL=63853:A=24046
66 IFINSTR("Ee",Q$)THENL=63864:A=20806
68 IFINSTR("Aa",Q$)THENL=63875:A=23400
70 IFINSTR("Ss",Q$)THENL=63886:A=23407
72 IFLTHENGOSUB96:RETURN
74 BEEP:GOTO28
76 B=INT(A/256):C=A-B*256:POKEL,176:POKEL+1,C:POKEL+2,B
78 FORN=1TO6:POKEL+2+N,ASC(MID$(P$,N,1)):NEXT:RETURN
80 Q$=INPUT$(1):IFQ$=CHR$(13)THENBEEP:GOTO6ELSERETURN
82 IFPEEK(1)=171THENRV=20360:NV=20365:DB=62045ELSERV=17001:NV=17006:DB=63853
84 FORX=DBTODB+33STEP11
86 PRINT"   ";:IFPEEK(X)=184THENCALLRV
88 FORY=3TO8:PRINTCHR$(PEEK(X+Y));:NEXT
90 CALLNV:NEXT:PRINT@242,"<T>       <E>     <A>      <S>   ";:RETURN
92 CLS:IFPEEK(1)=171THENT$="200"ELSET$="100/102"
94 PRINT@13,"CHGMNU."T$:RETURN
96 O$="":FORO=3TO8:O$=O$+CHR$(PEEK(L+O)):NEXT:RETURN