1 REM * Dsklst.100 * See Dsklst.txt for instructions
2 REM * D & R Rowland * 72277,1433
10 CLEAR1500:MAXFILES=2:WIDTH40:U$="\        \":N$="None Found":DEFINTA-Z
12 FORQ=0TO1
15 FORN=1TO15
17 FORM=0TO1
25 A$=DSKI$(0,20,N,M)
35 FORP=1TO127STEP16
40 Y$=MID$(A$,P,9)
42 IFLEFT$(Y$,1)=CHR$(255)THEN90
45 IFLEN(Y$)=0THEN80
50 IFASC(LEFT$(Y$,1))<32THEN80
55 Z$=MID$(A$,P+9,1)
60 IFZ$=CHR$(0)THEND=D+1:IFQTHEND$(D,0)=Y$
65 IFZ$=CHR$(1)THENC=C+1:IFQTHENC$(C,0)=Y$
70 IFZ$=CHR$(128)THENB=B+1:IFQTHENB$(B,0)=Y$
80 NEXTP,M,N
90 IFQ=0THENDIMB$(B+1,1),C$(C+1,1),D$(D+1,1):B=0:C=0:D=0
95 NEXTQ
100 N=1:M=D:CLS:PRINT@90,"TEXT FILES":PRINT
105 IFN>MTHENPRINTN$:GOTO150
107 IFN=MTHENPRINTD$(1,0):GOTO150
110 IFD$(N,0)>D$(N+1,0)THEND$(0,0)=D$(N,0):D$(N,0)=D$(N+1,0):D$(N+1,0)=D$(0,0):IFN>1THENN=N-1:GOTO110
120 N=N+1:IFN<MTHEN110
130 FORP=1TOM:IFD$(P,0)="INDEX    "THENPRINTCHR$(27);"p";:I=1
140 PRINTUSINGU$;D$(P,0);:PRINTCHR$(27);"q";:NEXT
150 N=1:M=B:PRINT:PRINT:PRINTSPACE$(10);"BASIC FILES":PRINT
155 IFN>MTHENPRINTN$:GOTO200
157 IFN=MTHENPRINTB$(1,0);:GOTO200
160 IFB$(N,0)>B$(N+1,0)THENB$(0,0)=B$(N,0):B$(N,0)=B$(N+1,0):B$(N+1,0)=B$(0,0):IFN>1THENN=N-1:GOTO160
180 N=N+1:IFN=MTHENFORP=1TOM:PRINTUSINGU$;B$(P,0);:NEXT:GOTO200
190 GOTO160
200 N=1:M=C:PRINT:PRINT:PRINTSPACE$(7);"MACHINE LANGUAGE FILES":PRINT
205 IFN>MTHENPRINTN$:GOTO300
207 IFN=MTHENPRINTC$(1,0):GOTO300
210 IFC$(N,0)>C$(N+1,0)THENC$(0,0)=C$(N,0):C$(N,0)=C$(N+1,0):C$(N+1,0)=C$(0,0):IFN>1THENN=N-1:GOTO210
220 N=N+1:IFN=MTHENFORP=1TOM:PRINTUSINGU$;C$(P,0);:NEXT:GOTO300
230 GOTO210
300 IFI=0THENPRINT@0,"DISC NAME";:INPUTD$(0,0)ELSEOPEN"0:INDEX"FORINPUTAS1:INPUT#1,D$(0,0):PRINT@0,D$(0,0):GOTO310
305 PRINT@0,SPACE$(5);"DISC IS CALLED";CHR$(27)"p";D$(0,0);CHR$(27);"q"
310 K$=INKEY$:IFK$=""THEN310
400 WIDTH80:IFI=0THEN600
410 N=0:INPUT#1,A$,A$
415 N=N+1:INPUT#1,A$:IFA$=""THEN430
420 FORM=1TOD:IFD$(M,0)=LEFT$(A$,9)THEND$(M,1)=RIGHT$(A$,LEN(A$)-4-LEN(D$(M,0)))
422 NEXT:GOTO415
430 N=0:INPUT#1,A$
435 N=N+1:INPUT#1,A$:IFA$=""THEN460
440 FORM=1TOB:IFB$(M,0)=LEFT$(A$,9)THENB$(M,1)=RIGHT$(A$,LEN(A$)-4-LEN(B$(M,0)))
445 NEXT:GOTO435
460 N=0: INPUT#1,A$
465 N=N+1:INPUT#1,A$:IFA$=""THEN490
470 FORM=1TOC:IFC$(M,0)=LEFT$(A$,9)THENC$(M,1)=RIGHT$(A$,LEN(A$)-(4+LEN(C$(M,0))))
475 NEXT:GOTO465
490 CLOSE1
600 OPEN"0:INDEX"FOROUTPUTAS1
610 PRINT#1,SPACE$(10);D$(0,0):PRINT#1,""
615 PRINTSPACE$(10);D$(0,0)
617 PRINT:PRINT"File Name         Description
618 PRINT:PRINTSPACE$(15);"TEXT FILES":E=5
620 PRINT#1,SPACE$(15);"TEXT FILES"
625 IFD=0THENPRINT#1,N$:PRINTN$:E=E+1:GOTO720
630 FORN=1TOD:PRINT#1,D$(N,0),:E=E+1
640 IFE=22THENGOSUB1200
670 PRINTD$(N,0),:IFD$(N,1)=""THENM$="":INPUTM$:IFM$="?"THENGOSUB1000:GOTO670ELSED$(N,1)=M$ELSEPRINTD$(N,1)
675 PRINT#1,D$(N,1)
680 NEXT:IFE>18THENGOSUB1200

720 PRINT#1,"":PRINT#1,SPACE$(15);"BASIC FILES"
722 PRINT:PRINTSPACE$(15);"BASIC FILES":E=E+3
725 IFB=0THENPRINT#1,N$:PRINTN$:E=E+1:GOTO820
730 FORN=1TOB:PRINT#1,B$(N,0),:E=E+1
740 IFE=22THENGOSUB1200
770 PRINTB$(N,0),:IFB$(N,1)=""THENM$="":INPUTM$:PRINT#1,M$ELSEPRINTB$(N,1):PRINT#1,B$(N,1)
780 NEXT:IFE>18THENGOSUB1200
820 PRINT#1,"":PRINT#1,SPACE$(10);"MACHINE LANGUAGE FILES"
822 PRINT:PRINTSPACE$(10);"MACHINE LANGUAGE FILES":E=E+3
825 IFC=0THENPRINT#1,N$:PRINTN$:E=E+1:GOTO920
830 FORN=1TOC:PRINT#1,C$(N,0),:E=E+1
840 IFE=22THENGOSUB1200
870 PRINTC$(N,0),:IFC$(N,1)=""THENM$="":INPUTM$:PRINT#1,M$ELSEPRINTC$(N,1):PRINT#1,C$(N,1)
880 NEXT
920 PRINT#1,"":CLOSE1:CLEAR:END
1000 Z$="0:"+D$(N,0):OPENZ$FORINPUTAS2
1005 ONERRORGOTO1070
1010 IFEOF(2)THENPRINT:GOTO1070
1020 INPUT#2,Z$:PRINTZ$:E=E+1
1030 K$=INKEY$
1040 IFK$=CHR$(13)THENGOTO1070
1050 IFK$="?"THEN1010
1060 GOTO1030
1070 CLOSE2:RETURN
1200 PRINT:PRINTSPACE$(8);CHR$(27);"p";"PRESS ANY KEY TO CONTINUE";CHR$(27);"q"
1210 K$=INKEY$:IFK$=""THEN1210
1220 PRINT@80*CSRLIN-80,SPACE$(60)
1230 PRINT@80*CSRLIN-160,"";:E=0:RETURN