101 'PRTDIR.BA
102 MAXFILES=1:CLEAR5000:DIMN$(123):DEFINTA-B
104 D$="/":F$="INDEX.DO
112 LPRINTCHR$(27);CHR$(20)
122 CLS:PRINT@47,"The Executive Disk Directory
124 IF(INP(187)AND6)=2THEN126ELSEGOSUB202:GOTO122
126 PRINT@166,"Now Reading the "F$" file
130 OPENF$FORINPUTAS1:A=1
132 PRINT@258,USING"###";A:IFEOF(1)THEN 160
134 LINEINPUT#1,I$:IFI$=""THENI$=" ":GOTO154
136 IFLEN(I$)<41THEN152
140 P=INSTR(I$,D$):IFP=0THEN148
142 IFP<39THENN$(A)=LEFT$(I$,P-1):A=A+1:N$(A)=" "+STRING$(39-P,".")+MID$(I$,P+1):GOTO158
144 FORB=40TO1STEP-1:IFMID$(I$,B,1)=" "THEN146ELSENEXT
146 N$(A)=LEFT$(I$,B):I$=MID$(I$,B):A=A+1:GOTO136
148 FORB=40TO1STEP-1:IFMID$(I$,B,1)=" "THEN150ELSENEXT
150 N$(A)=LEFT$(I$,B):I$=MID$(I$,B):A=A+1:GOTO136
152 P=INSTR(I$,D$):IFPTHEN156
154 N$(A)=I$:GOTO158
156 N$(A)=LEFT$(I$,P-1)+STRING$(39-LEN(I$),".")+" "+MID$(I$,P+1)
158 A=A+1:IFA=>121THEN160ELSE132
160 CLOSE:GOSUB190
164 F=0:LPRINTX$
166 LPRINTTAB(80)"DISK DIRECTORY  ";DATE$
168 FORA=0TO30
170 IFFTHENLPRINTTAB(24)N$(A+31)TAB(74)N$(A+62):GOTO174
172 LPRINTTAB(24)N$(A+93)TAB(74)N$(A)
174 NEXT:LPRINT:GOTO180
180 LPRINTY$:IFFTHEN182ELSEF=1:GOSUB196 :LPRINT:LPRINT:GOTO168
182 BEEP:CLS:PRINT@42,"Job Completed!
184 LPRINTW$:MENU
190 CLS:PRINT@42,"Now ready to send output to printer.":PRINT"  Line up perforations or reference
192 PRINT"  mark per instructions, and press":PRINT"  ENTER when ready to continue.  ";
194 Q$=INPUT$(1):GOSUB200:CLS:PRINT@42, "You should have printer output now.":RETURN
196 PRINT@42,"Part 1 finished. Now turn paper over":PRINT"  and line up perforations exactly,
198 PRINT"  then press ENTER to continue: ";:GOTO194
200 IF(INP(187)AND6)=2THENRETURNELSECLS:PRINT@42,"Oops..."
202 BEEP:PRINT@164,"Printer not ready. Setup printer
204 PRINT@204,"and press ENTER to continue: ";:Q$=INPUT$(1):RETURN