8 REM WRITTEN IN MICROSOFT FOR RS MODEL 200
10 REM SLOT MACHINE PROGRAM
12 REM PROGRAMMED BY LEO FINKELSTEIN JR.
13 CLS:WC=1
15 INPUT"INITIAL AMOUNT IN ACCOUNT";AC
20 CLS:LINE(13,4)-(226,50),1,B:LINE(84,4)-(155,50),1,B:LINE(11,2)-(228,52),1,B
25 PRINT@293,"* SLOT MACHINE *"
30 PRINT@323,"ACCT BAL=$";AC;"HIT ANY NUMBER TO BET"
31 IF L+75 >=239 THEN GOSUB 7000
32 IF W+75 >=239 THEN GOSUB 7000
33 PRINT@361,"WINNINGS:":LINE(75,73)-(75+W,78),1,BF:PRINT@401,"LOSSES:":LINE(75,80)-(75+L,85),1,BF:FORZ=75TO238STEP4:LINE(Z,72)-(Z,86):NEXT
35 LINE(0,88)-(239,110),1,B:LINE(0,0)-(239,125),1,B:FORX=0TO239STEP2:LINE(X,88)-(X,110):NEXTX:PRINT@485,"FINKEL-SLOT GRAPH FACTOR ="1/WC;
37 PRINT@563,"OXX or XXO pays 2:1 - XXX pays 10:1"
40 BT$=INKEY$:IFBT$=""THEN40
50 IFASC(BT$)<49ORASC(BT$)>57THEN40
55 BT=VAL(BT$):IFBT>ACTHEN40
56 PRINT@289,"    NOW BETTING$";BT;"    "
60 SEC=VAL(RIGHT$(TIME$,2))
70 FORI=1TOSEC
80 DUMMY=RND(1)
90 NEXTI
92 MM=39
93 FORX=281TO320
94 PRINT@MM,CHR$(238):SOUND14000,2
95 FORX=1TO50:NEXTX:PRINT@MM,CHR$(153);
96 MM=MM+40:IFMM>388THEN100ELSE94
100 A=INT(RND(1)*4)
110 IFA<1ORA>5THEN100
120 B=INT(RND(1)*9)
130 IFB<1ORB>7THEN120
140 C=INT(RND(1)*9)
150 IFC<1ORC>9THEN140
165 IFAC>0THENLETR$=""
200 ONAGOSUB1000,1010,1020,1030,1040
205 A$=D$
210 ONBGOSUB1000,1010,1020,1030,1040,1050,1060,1070
215 B$=D$
220 ONCGOSUB1000,1010,1020,1030,1040,1050,1060,1070,1080
225 C$=D$
300 FORX=1TO10:NEXTX
305 PRINT@83,A$:PRINT@95,B$:PRINT@107,C$
310 PRINT@123,A$:PRINT@135,B$:PRINT@147,C$
315 PRINT@163,A$:PRINT@175,B$:PRINT@187,C$
320 E=E+1:IFE>(15*C)THEN330
322 SOUND(E*300+500),5
325 GOTO100
330 FORDL=1TO500:NEXTDL
335 E=0:GOTO400
400 IFA=BANDB=CTHENGOTO4000
402 IFA=BORB=CTHENGOTO3000
405 GOTO5000
410 FORX=1TO300:NEXTX:CLS
420 PRINT"NEW ACCOUNT BALANCE = ";
425 IF AC=<0THENGOTO6000
430 PRINT USING"$$##,###.##";AC
440 FORX=1TO375:NEXTX:GOTO20
1000 D$=STRING$(10,144):RETURN
1010 D$=STRING$(10,145):RETURN
1020 D$=STRING$(10,156):RETURN
1030 D$=STRING$(10,157):RETURN
1040 D$=STRING$(10,158):RETURN
1050 D$=STRING$(10,159):RETURN
1060 D$=STRING$(10,147):RETURN
1070 D$=STRING$(10,144):RETURN
1080 D$=STRING$(10,149):RETURN
3000 CLS: FORX=0TO27:PRINT@(X*10),"A WINNER!!";:BEEP:NEXTX:AC=AC+BT*2:W=W+BT*2:GOTO410
4000 CLS:FORX=1TO25:PRINT"BIG WINNER !!!";:BEEP:NEXTX:AC=AC+(BT*10):W=W+BT*10:GOTO410
5000 CLS:FORX=1TO15:PRINT TAB(15);"YOU LOSE":SOUND5000,5:NEXTX:AC=AC-BT:L=L+BT:GOTO410
6000 CLS:PRINT "GAME OVER - YOU'RE BROKE"
6005 PRINT:PRINT"ANOTHER GAME YES(Y) NO(N)?"
6010 Y$=INKEY$
6011 IFY$="Y"THENRUN
6012 IFY$="N"THENMENU
6013 GOTO6010
7000 L=L*.5:W=W*.5:WC=WC+1:RETURN