0 'see documenation TD200.Doc
1 'Modified for the T200 by Curtis Karnow, 73047,3120
10 MAXFILES=2:CLEAR1000:DEFSTRA-M:B="note.do":OPENBFORAPPENDAS1:CLOSE:E=LEFT$(DATE$,5):H=CHR$(27)+"p":I=CHR$(27)+"q":P=322:CLS
11 OPEN"alarm.do"FORINPUTAS1:TG$=INPUT$(1,#1):CLOSE:IFINSTR(TG$,"F")<>0THENXT=7ELSEXT=1
15 GOSUB90:PRINT@600,"View  Entr     Alrm       Cal      Menu";:PRINT@632,CHR$(146);:PRINT@612,CHR$(135);
16 LINE(6,56)-(233,118),1,B:KEYON:ONKEYGOSUB100,200,800,400,500,600,700,80:PRINT@281,H;"     Nota bene                        ";I
17 LINE(139,2)-(159,54),1,B:PRINT@103,"CEAK"
20 IFEOF(1)THEN30 ELSEIF P>600 THEN30ELSELINEINPUT#1,L:IFINSTR(L,E)<>0THEN25ELSEIFINSTR(L,"TO-DO")<>0THEN25ELSE20
25 IFINSTR(TG$,"T")<>0ORINSTR(L,MID$(DATE$,1,5))<>0ORINSTR(L,"TO-DO")>0THENPRINT@P,MID$(L,XT,36):P=P+40:GOTO20:ELSEGOTO20
30 A="alarm.do":LINE(161,0)-(233,56),1,B:PRINT@27,H;"  Today is  ":PRINT@147,"The Time is ";:PRINT@227,"   Alarm    ";I
33 PRINT@109,DATE$:IFDAY$="Sun"THENC="Sunday"ELSEIFDAY$="Mon"THENC="Monday"ELSEIFDAY$="Fri"THENC="Friday"
34 PRINT@70,C:IFDAY$="Tue"THENF="Tuesday"ELSEIFDAY$="Wed"THENF="Wednesday"
35 IFDAY$="Thu"THENF="Thursday"ELSEIFDAY$="Sat"THENF="Saturday"
36 PRINT@69,F
40 M=TIME$:K=LEFT$(TIME$,5):E=LEFT$(DATE$,5):IFEOF(1)THENCLOSE:OPENAFORINPUTAS1
45 LINEINPUT#1,L:IFINSTR(L,"  ***")=0THEN50ELSEIFINSTR(L,K)=0THEN50ELSE55
50 IFINSTR(L,E)=0THEN65ELSEIFINSTR(L,K)=0THEN65
55 CLS:PRINT@207,H;" Press Any Key To Silence ";I
60 J=INKEY$:FORY=2000TO1000STEP-50:SOUNDY,1:NEXTY:SOUND9999,25:N=N+1:IFN=99THENRUNELSEIFJ=""THEN60ELSEFORR=1TO25000:NEXT:RUN
65 IFM=TIME$THEN65ELSEIFINSTR(L,E)<>0ORINSTR(L,"  ***")<>0THENPRINT@270,MID$(L,8,5)
70 S=VAL(LEFT$(TIME$,2)):IFS>12THENPRINT@187,STR$(S-12);RIGHT$(M,6)ELSEIFS<10THENPRINT@187,STR$(S);RIGHT$(M,6)ELSEPRINT@188,M;
75 IFS>11THENPRINT@196,"PM";ELSEIFS<12THENPRINT@196,"AM";
77 IFTIME$="00:00:01"THENRUNELSE40
80 MENU
90 CLOSE:OPENBFORINPUTAS1:RETURN
100 GOSUB90:OPEN"t.do"FORAPPENDAS2:PRINT@57,H;" Select: "I:PRINT@97," 1)Scan  ":PRINT@137," 2)MM/DD "
101 PRINT@177," 3)Today ":PRINT@217," 4)TO-DO ":PRINT@257,STRING$(8,32):PRINT@260,"";:LINE(101,7)-(155,56),1,B
105 J=INKEY$:N=VAL(J):IFN<1ORN>4THEN105ELSEN=N:ONNGOSUB110,115,120,125
110 K="S":GOTO135
115 GOTO130
120 K=E:GOTO135
125 K="TO-DO":GOTO135
130 LINEINPUT"";K
135 IFEOF(1)THENCLOSE:KILLB:NAME"t.do"ASB:RUNELSELINEINPUT#1,L:IFINSTR(L,K)<>0ORK="S"THEN140ELSEPRINT#2,L:GOTO135
140 CLS:N=LEN(L):IFN<40THENPRINT@80+(40-N)/2,LELSEPRINT@80,L
150 PRINT@253,H;" Delete (Y/N) "I;:J=INPUT$(1):IFINSTR("Yy",J)>0THEN135ELSEPRINT#2,L:CLS:GOTO135
154 IFINSTR(L,E)=0THEN65ELSEIFINSTR(L,K)=0THEN65
200 PRINT@171,H;"   Select:< >  "I:PRINT@211," <T>o-Do      ":PRINT@251," <A>ppointment"
201 LINE(66,39)-(155,56),1,B:CLOSE:OPENBFORAPPENDAS1
205 J=INKEY$:IFJ="a"ORJ="A"THEN210ELSEIFJ="t"ORJ="T"THEN220ELSE205
210 CLS:PRINT@12,"Today is "E:PRINT@52,"Time is "K:PRINT@131,"Date: Time: Appointment:":PRINT@171,;
215 LINEINPUT"";M:PRINT#1,M:CLS:PRINT@129,H" Another Appointment? "I;:J=INPUT$(1):IFINSTR("Yy",J)>0THEN210ELSE230
220 CLS:PRINT@131,;:LINEINPUT"To-Do:";M:PRINT#1,"TO-DO "M:CLS:PRINT@132,H" Another To-Do? "I;
225 J=INPUT$(1):IFINSTR("Yy",J)>0THEN220
230 GOSUB90:DIMA(100):CLS:PRINT@169,H" Reorganizing File "I:N=1:O=11:P=0
235 P=P+1:LINEINPUT#1,A(P):IFEOF(1)THEN240ELSE235
240 CLOSE1:GOSUB245:KILLB:OPENBFOROUTPUTAS1:FORQ=1TOP:PRINT#1,A(Q):NEXT:RUN
245 U=P
250 U=INT(U/2):IFU=0THENRETURNELSER=1:S=P-U
255 Q=R
260 T=Q+U:IF(MID$(A(Q),N,(O-N)+1))<(MID$(A(T),N,(O-N)+1))THEN270
265 G=A(Q):A(Q)=A(T):A(T)=G:Q=Q-U:IFQ<1THEN270ELSE260
270 R=R+1:IFR>STHEN250ELSE255
400 C=STRING$(14,32):PRINT@12,H;" ** Alarm **  "I:PRINT@52,"   <S>et      ":PRINT@92,"   <C>ancel   "
401 PRINT@132,C:PRINT@172,C:PRINT@212,C:PRINT@252,C:LINE(72,7)-(155,56),1,B
405 J=INKEY$:IFJ="s"ORJ="S"THEN410ELSEIFJ="c"ORJ="C"THEN430ELSE405
410 CLOSE:OPENAFORAPPENDAS1:PRINT@55,"<D>aily":PRINT@95,"<S>ingle"
415 J=INKEY$:IFJ="d"ORJ="D"THEN420ELSEIFJ="s"ORJ="S"THEN425ELSE415
420 PRINT@176,"Time:":PRINT@216,"";:LINEINPUT"";D:PRINT#1,"  ***  "D:CLOSE:RUN
425 PRINT@173,"Date:  Time:":PRINT@213,"";:LINEINPUT"";D:PRINT#1,D:CLOSE:RUN
430 CLOSE:OPENAFORINPUTAS1:OPEN"temp.do"FORAPPENDAS2
435 IFEOF(1)THENCLOSE:KILLA:NAME"temp.do"ASA:RUNELSELINEINPUT#1,L
440 PRINT@173,LEFT$(L,12):PRINT@252,H;" Cancel (Y/N) "I:J=INKEY$:IFJ=""THEN440ELSEIFJ="y"ORJ="Y"THEN435ELSEPRINT#2,L:GOTO435
500 RETURN
600 KEYOFF:D="":GOSUB608
602 Y=-INT((14-W)/12):Z=X-32074+INT(1461*(V+4800+Y)/4):Z=Z+INT(367*(W-2-12*Y)/12):N=Z-INT(3*INT((V+4900+Y)/100)/4):RETURN
604 DATAJanuary,31,February,28,March,31,April,30,May,31,June,30,July,31,August,31
605 DATASeptember,30,October,31,November,30,December,31,EOF,-1
606 LINE(6,47)-(137,56),1,B:PRINT@241,H;" Month/Year "I"         ";:PRINT@253,"";:INPUT"";D
608 GOSUB602:RESTORE604:IFD=""THEND=DATE$:O%=VAL(MID$(D,4,2)):D=LEFT$(D,3)+RIGHT$(D,2)
610 P%=INSTR(D,"/"):IFP%<2ORP%>3ORP%=LEN(D)THENBEEP
612 W=VAL(LEFT$(D,P%-1)):V=VAL(RIGHT$(D,LEN(D)-P%)):X=1
614 IFW<1ORW>12ORV<0THENBEEP:GOTO606ELSEIFV<100THENV=V+1900
616 GOSUB602:FORP%=1TOW:READA,Q%:NEXTP%:IFW=2THENQ%=Q%-(0=VMOD4)+(0=VMOD100)-(0=VMOD400)
618 PRINT@600,"Menu      Time Next Prev Any  Tody Retn";:KEYON:ONKEYGOSUB80,,800,634,630,606,600,700
620 LINE(6,0)-(137,7),1,BF:PRINT@2,H;A;:PRINT@17,V;I;
621 PRINT@42,"Su Mo Tu We Th Fr Sa":R%=N-7*INT(N/7):PRINTTAB(1);SPACE$(3*R%);
622 FORP%=1TOQ%:IFP%=O%THENPRINT" ";:PRINTH;ELSEPRINT" ";
624 PRINTUSING"##";P%;:IFP%=O%THENPRINTI;
626 R%=R%+1:IFR%>6ANDP%<>Q%THENPRINT:PRINTTAB(1);:R%=0
628 NEXTP%:LINE(6,7)-(137,56),1,B:GOSUB30
630 C=STR$(VAL(LEFT$(D,2))-1):C=RIGHT$(C,2)+"/"+RIGHT$(D,2):D=C:O%=0
632 IFVAL(LEFT$(D,2))=0THENC=STR$(12)+"/"+RIGHT$(STR$(VAL(RIGHT$(D,2))-1),2):D=RIGHT$(C,5)
633 GOTO608
634 C=STR$(VAL(LEFT$(D,2))+1):C=RIGHT$(C,2)+"/"+RIGHT$(D,2):D=C:O%=0
636 IFVAL(LEFT$(D,2))=13THENC=STR$(1)+"/"+RIGHT$(STR$(VAL(RIGHT$(D,2))+1),2):D=RIGHT$(C,5)
638 GOTO608
700 CLOSE:OPEN"alarm.do"FORINPUTAS1:TG$=INPUT$(1,1)
710 OPEN"temp.do"FOROUTPUTAS2
715 IFINSTR(TG$,"F")<>0THENTG$="T"ELSETG$="F"
716 PRINT#2,TG$;
720 IFEOF(1)THENGOTO730ELSES$=INPUT$(1,1):PRINT#2,S$;:GOTO720
730 CLOSE:KILL"alarm.do":NAME"temp.do"AS"alarm.do":RUN
800 LINE (139,2)-(159,54),1,B:PRINT@23,CHR$(135);:PRINT@24,"ime";
805 Z=VAL(LEFT$(TIME$,2))
806 Z2=VAL(MID$(TIME$,4,2))
810 SN=Z+3'ADD 3 HRS FOR NY
815 PRINT@63,H+CHR$(157)+"NYC"I;
820 IF SN>24 THEN SN=SN-24
830 IF SN>12 THEN PRINT@102,STR$(SN-12);
836 IF SN<=12 THEN PRINT@102,SN;
840 IF SN>11 THEN PRINT@145,"PM" ELSE PRINT@145,"AM";
850 SL=Z+8 'ADD 8 HRS FOR LON
855 PRINT@183,H+CHR$(157)+"LON"I
860 IF SL>24 THEN SL=SL-24
870 IF SL>12 THEN PRINT@222,STR$(SL-12);
876 IF SL<=12 THEN PRINT@222,SL;
880 IF SL>11 THEN PRINT@265,"PM" ELSE PRINT@265,"AM";
885 PRINT@104,Z2;:PRINT@224,Z2;
890 RETURN