10 'written for the NEC 8201A
20 'by eric anderson, 73715,1501
100 CLEAR:DIM A$(100),D$(100),C$(100),P$(100),CASH(100)
120 CLS:PRINT"1. Check entry":PRINT"2. Account tally":PRINT"3. Deposits":PRINT"4: Balance":PRINT"5. Menu"
121 IFLP=0THENPRINT"6. Printer OFF":GOTO125
122 IFLP=1THENPRINT"6. Printer ON"
125 INPUT"Which";R
130 ON R GOTO 190,300,500,600,135,150
135 MENU
150 IFLP=1THENLP=0:GOTO120
155 IFLP=0THENLP=1:GOTO120
190 OPEN"RAM:checks.do"FORAPPENDAS1
200 CLS:INPUT "Account ";A$
210 INPUT "Date ";D$
220 INPUT "Check #";C$
230 INPUT "Payee ";P$
240 INPUT "Amount ";CASH
245 INPUT "Is this correct"; R$
246 IF R$="Y"OR R$="y" THEN 250
247 GOTO 200
250 PRINT#1,A$;",";D$;",";C$;",";P$;",";CASH
260 CLOSE
270 GOTO 120
300 CLS:R=0:TALLY=0:ON ERROR GOTO 400
310 OPEN"checks.do"FORINPUTAS1
315 R$=""
320 LOCATE 0,0:INPUT "Keyword"; R$
321 IFLP=1THENLPRINT R$
325 PRINT"DATE     CHECK   PAYEE            AMT"
326 IFLP=1THENLPRINT"DATE    CHECK   PAYEE            AMOUNT"
330 INPUT#1,TEMP$
340 IF INSTR(TEMP$,R$)=0 THEN 330
350 INPUT#1,D$,C$,P$,M
355 P$=LEFT$(P$,15):IFM<100THENY=32ELSEY=31
360 PRINT D$;"  ";C$;"  ";P$;"  ";TAB(Y);M
361 SP=0:IFM<100THENSP=1
362 IFLP=1THENLPRINT D$;"   ";C$;"   ";P$;"     ";SPACE$(15-LEN(P$)+SP);M
370 TALLY=TALLY+M:R=R+1
380 IFR=4THENR=0:INPUT"Press return to continue";R$:CLS
390 GOTO 330
400 IF EOF(1) THEN CLOSE#1
410 PRINT"Account total=";TALLY
411 IFLP=1THENLPRINT"Account total=";TALLY
415 INPUT "Press return to continue";R$
420 CLOSE:RESUME 120:GOTO 120
500 CLS
510 OPEN "depsit.do"FOR APPENDAS1
520 INPUT "Date";D$
530 INPUT "Source";P$
540 INPUT "Amount";M
550 INPUT "Is this correct";R$
560 IF R$="y" THEN 580
570 GOTO 520
580 PRINT#1,D$;",";P$;",";M
590 CLOSE#1:GOTO 120
600 CLEAR:Z=0:CLS
605 OPEN "checks.DO" FORINPUTAS1:ONERROR GOTO 630
606 IFEOF(1) THEN 630
607 INPUT#1,D$,C$,A$,P$,C:Z=Z+C:GOTO 607
630 CLOSE
650 OPEN"depsit.do"FORINPUTAS1
660 IF EOF(1)THEN680
665 INPUT#1,D$,P$,N:Y=Y+N:GOTO 660
680 CLOSE
690 PRINT"Check book= ";Y-Z
695 INPUT"Press return";R$:GOTO 120