1 SCREEN,0:LOCATE16,3:PRINT"LOADING":CLEAR1000:MAXFILES=2:DEFINTA-Z:DEFDBLM,L:DIM D$(50),A$(50),MD(50)
2 CLS
3 GOSUB15
4 RESTORE:CLS:PRINT
5 FORI=0TO2STEP2
6 LINE(1+I,1+I)-(238-I,62-I),1,B
7 NEXTI
8 LOCATE10,0:PRINTCHR$(27)"p";"  ";MID$(DATE$,4,5);"     ";LEFT$(TIME$,5);"  ";CHR$(27)"q"
9 LOCATE10,2:PRINT" <L>ist records":LOCATE10,3:PRINT" <A>dd a record":LOCATE10,4:PRINT" <U>pdate records"
10 LOCATE10,5:PRINT" <S>ort (by date)":LOCATE10,6:PRINT" <E>xit"
11 A$=INPUT$(1)
12 K=INSTR(" LlAaUuSsEe",A$)\2
13 IFK=0THENBEEP:GOTO11
14 ONKGOSUB49,21,29,64,75:GOTO4
15 '   READ APPOINTMENTS
16 OPEN"RAM:NOTE.DO"FORINPUTAS1
17 IFEOF(1)THENCLOSE:RETURN
18 FORN=1TO50:INPUT#1,D$(N),A$(N)
19 IFEOF(1)THENCLOSE:N=N+1:RETURN
20 NEXTN
21 '   ADD APPOINTMENTS
22 OPEN"RAM:NOTE.DO"FORAPPENDAS2
23 CLS:SCREEN,1:PRINT" ";MID$(DATE$,4,5):PRINTTAB(9);"ENTER MM/DD/YY,ACTION":KEY1,"Today,":PRINT:PRINT:PRINT
24 FOR J=12TO221STEP6:LINE(J,50)-(J+4,50):NEXTJ:LINE(221,39)-(221,50)
25 INPUT"";D$(N),A$(N)
26 IF D$(N)="Today"THEN D$(N)=MID$(DATE$,4,5)
27 PRINT#2,D$(N);",";A$(N)
28 CLOSE:KEY1,"Load"+CHR$(34):SCREEN,0:GOSUB15:RETURN
29 '   DELETE RECORDS
30 CLS:LOCATE1,0:PRINTMID$(DATE$,4,5):LOCATE 11,0:PRINT"DELETE RECORDS":PRINT
31 PRINTTAB(7);" <D>ELETE OLD RECORDS"
32 PRINTTAB(7);" <U>PDATE RECORDS"
33 PRINTTAB(7);" <M>AIN MENU"
34 GOSUB79
35 T1$=INPUT$(1)
36 L=INSTR(" DdUuMm",T1$)\2:IFL=0THENBEEP:GOTO35
37 ONLGOSUB39,61:IFL=3THEN4
38 GOTO30
39 CLS:PRINT:PRINT:INPUT"MOST RECENT DATE TO RETAIN";R$
40 CLS:LOCATE 16,3:PRINT"DELETING"
41 MS=VAL((MID$(R$,7,2))+(MID$(R$,1,2))+(MID$(R$,4,2)))
42 GOSUB77
43 OPEN"RAM:NOTE.DO"FOROUTPUTAS2
44 FORT=1TON-1
45 IFMD(T)>=MSTHEN48
46 NEXTT
47 CLOSE:GOSUB76:GOSUB15:RETURN
48 PRINT#2,D$(T);",";A$(T):GOTO46
49 ' SEARCH AND DELETE
50 C1=1:C2=6
51 CLS:FORT=C1TOC2:IFD$(T)=MID$(DATE$,4,5)THENPRINTT;CHR$(27)"p";D$(T);" ";LEFT$(A$(T),30)+CHR$(27)"q":NEXTT:GOTO53:ELSEGOTO52
52 PRINTT;D$(T);" ";LEFT$(A$(T),30):NEXTT
53 T1=0:LOCATE0,8:INPUT"   <ENTER> FOR MORE    # TO DELETE";T1
54 IF T1=0 THENC1=C1+6:C2=C2+6:IFD$(C2-5)=""THENRETURNELSE51
55 IFT1<C1ORT1>C2THENGOTO51
56 CLS:LOCATE16,3:PRINT"DELETING"
57 FORT=T1TON:D$(T)=D$(T+1):A$(T)=A$(T+1):NEXTT
58 OPEN"RAM:NOTE.DO"FOROUTPUTAS2
59 FORT=1TON-2:PRINT#2,D$(T);",";A$(T):NEXTT
60 CLOSE:GOSUB76:GOSUB15:RETURN
61 CLS:LOCATE16,3:PRINT"UPDATING":FOR J=1TON:IF D$(J)<MID$(DATE$,4,5)THEN D$(J)=MID$(DATE$,4,5):NEXTJ
62 OPEN"RAM:NOTE.DO"FOROUTPUTAS2
63 FORJ=1TON:PRINT#2,D$(J);",";A$(J):NEXTJ:CLOSE2:RETURN
64 '   SORT FILE
65 CLS:LOCATE13,3:PRINT"   SORTING   "
66 OPEN"RAM:NOTE.DO"FOROUTPUTAS2
67 GOSUB77
68 LD=991231!:FORT1=1TON-1:FORT=1TON-1
69 IFMD(T)<LDTHENLD=MD(T):PI=T
70 NEXTT
71 IFLD=991231!THEN74
72 PRINT#2,D$(PI);",";A$(PI):MD(PI)=999999!:LD=991231!
73 NEXTT1
74 CLOSE:GOSUB76:GOSUB15:RETURN
75 CLOSE:KEY1,"Load "+CHR$(34):CLS:SCREEN,1:MENU
76 FORT=1TON:D$(T)="":A$(T)="":NEXTT:RETURN
77 FORT=1TON-1:MD(T)=VAL((MID$(D$(T),7,2))+(MID$(D$(T),1,2))+(MID$(D$(T),4,2))):NEXTT:RETURN
78 I$=INKEY$:IFI$=""THEN78ELSERETURN
79 X=230:Y=5:U=5:V=53
80 FORI=1TO5:LINE(X,Y)-(X,57):LINE(U,V)-(230,V):X=X+1:Y=Y+1:U=U+1:V=V+1:NEXTI:RETURN
81 'Adapted for the NEC 8201A from SCHDUL.100 by Roger L. Strand 71675,335, by Steve Sagman (72456,3325)
82 'Requires LINE.LDR and LINE.CO from XA7 Database
83 '<L>ist - today's appts. displayed in reverse video
84 '<A>dd - characters beyond max. length indicated will not be displayed upon <L>isting.  F1 function key automatically inserts today's dat
85 REQUIRES NOTE.DO FILE.  APPTS ARE ENTERED AS <MM/DD,TIME APPT.> (EX. 09/12,1:30PM SECRET RENDEZVOUS)
86 'please forward enhancements to Steve Sagman (72456,3325)